Bold Cell When Choose, UnBold When Choose Again

[03856me]

I have a list of 30 items in column A on a simple worksheet, when a user chooses any or many of the items by clicking their mouse directly on the item, I would like the item to turn a different color or bold. Then I would like to write a formula in column B that would calculate the value of only those items selected. Is this possible? Should build a UserForm or simply have this in a spreadsheet?

 

[HalfAce]

How about something like this to get you started?
Assuming your values are in A1:A30, this in the worksheet module should help.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Intersect(Target, Range("A1:A30")) Is Nothing Then Exit Sub
With Selection
  .Font.Bold = Not .Font.Bold
End With

MsgBox Application.WorksheetFunction.Sum(Range(Selection.Address))

End Sub

Hope it helps.

 

[Ruddles]

D'oh - I've been doing this whilst watching the telly!

Option Explicit
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 
  Dim uRange As Range
  Dim oC As Range
  Dim BoldOn As Range
  Dim BoldOff As Range
 
  Set uRange = Range("A1:A30")
  Set BoldOn = Range("B1")
  Set BoldOff = Range("B2")
 
  If Intersect(Target, uRange) Is Nothing Then Exit Sub
 
  For Each oC In Intersect(Target, uRange)
    oC.Font.Bold = Not oC.Font.Bold
    oC.Font.Color = vbBlack + vbRed - oC.Font.Color
  Next oC
 
  Range("B1") = 0
  Range("B2") = 0
  For Each oC In uRange
    If oC.Font.Bold = True Then
      Range("B1") = Range("B1") + 1
    Else
      Range("B2") = Range("B2") + 1
    End If
  Next oC
 
End Sub

 

[03856me]

Thanks, worked like a charm, very cool