Bold a Specific text or Number in formula

[majhar420]

I want to Join two cell with "&" A1=13 and B1="Name" . when Join these two ,i want "Name" show Bold letter.

 

[Rick Rothstein]

I want to Join two cell with "&" A1=13 and B1="Name" . when Join these two ,i want "Name" show Bold letter.

You cannot do that using formulas... Excel will only permit text within a single cell to have multiple font formats if that text is a constant (that is, not produced by a formula). What you want to do is possible using VBA event code... you would no longer have a formula in the cell, rather, the VBA code would perform the concatenation and then format the text for you. Would you be up for using a VBA solution? If so, you will need to tell us all of the cells that the code needs to monitor and where the output should go to.

 

[majhar420]

It would be fine if i get VBA solution . I want use concatenation column A and B . The out put in column C.

 

[Rick Rothstein]

It would be fine if i get VBA solution . I want use concatenation column A and B . The out put in column C.

Give this event code a try...

[table="width: 500"]
[tr]
	[td]Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Cell As Range
  If Not Intersect(Target, Columns("A:B")) Is Nothing Then
    Application.EnableEvents = False
    For Each Cell In Intersect(Target, Columns("A:B"))
      Cells(Cell.Row, "C").Value = Cells(Cell.Row, "A").Value & Cells(Cell.Row, "B").Value
      Cells(Cell.Row, "C").Characters(Len(Cells(Cell.Row, "A").Value) + 1).Font.Bold = True
    Next
    Application.EnableEvents = True
  End If
End Sub[/td]
[/tr]
[/table]

HOW TO INSTALL Event Code
------------------------------------
If you are new to event code procedures, they are easy to install. To install it, right-click the name tab at the bottom of the worksheet that is to have the functionality to be provided by the event code and select "View Code" from the popup menu that appears. This will open up the code window for that worksheet. Copy/Paste the event code into that code window. That's it... the code will now operate automatically when its particular event procedure is raised by an action you take on the worksheet itself. Note... if you are using XL2007 or above, make sure you save your file as an "Excel Macro-Enabled Workbook (*.xlsm) and answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.