Blinking text in excel sheet

[AFZAL SOHAIL]

Hi, respected Team:-
Can we add blinking text in excel, or how can we do it blinking?
Thanks in advance please.

 

[arthurbr]

be aware that blinking text can triggers seizures when one is prone to photosensitive epilepsy

 

[AFZAL SOHAIL]

be aware that blinking text can triggers seizures when one is prone to photosensitive epilepsy

Thanks a lot Sir, for this very good information.

 

[Logit]

Public RunWhen As Double

Sub StartBlink()
    With ThisWorkbook.Worksheets("Sheet1").Range("A1").Font
        If .ColorIndex = 3 Then ' Red Text
            .ColorIndex = 2 ' White Text
        Else
            .ColorIndex = 3 ' Red Text
        End If
    End With
    RunWhen = Now + TimeSerial(0,0,1)
    Application.OnTime RunWhen, "'" & ThisWorkbook.Name & "'!StartBlink", , True
End Sub

Sub StopBlink()
    ThisWorkbook.Worksheets("Sheet1").Range("A1").Font.ColorIndex = _
        xlColorIndexAutomatic
    Application.OnTime RunWhen, "'" & ThisWorkbook.Name & "'!StartBlink", , False
End Sub

Then, in the ThisWorkbook code module of the workbook, use code like:

Private Sub Workbook_Open()
    StartBlink
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    StopBlink
End Sub

Blinking Text In Excel

 

[AFZAL SOHAIL]

Mr.Logit,
Thansk a lot sir, it is working only a1 cell, how we will increase the cell range?