Bind chart data without selecting/activating

[KillGorack]

Hi,

Past practices here work of course, just would like the syntax for doing this without selecting stuff.

    ' Good greif can we do this without selecting stuff??!
    ThisWorkbook.Sheets(sht).Select
    ActiveSheet.ChartObjects("trend_" & shp).Activate
    
    ' Nominal Line
    With ActiveChart.FullSeriesCollection(1)
        .Name = "=data!$C$" & dataLocation + 1
        .Values = "=data!$D$" & dataLocation + 1 & ":$" & DataWidthLetter & "$" & dataLocation + 1
        .XValues = "=data!$D$" & dataLocation + 6 & ":$" & DataWidthLetter & "$" & dataLocation + 6
        .Format.Line.Visible = msoTrue
        .Format.Line.Weight = 0.25
        .Format.Line.ForeColor.RGB = RGB(0, 0, 0)
    End With

Tried someting like... to no avail...

  ' Nominal Line
  With ThisWorkbook.Sheets(sht).ChartObjects("trend_" & shp).FullSeriesCollection(1)
      .Name = "=data!$C$" & dataLocation + 1
      .Values = "=data!$D$" & dataLocation + 1 & ":$" & DataWidthLetter & "$" & dataLocation + 1
      .XValues = "=data!$D$" & dataLocation + 6 & ":$" & DataWidthLetter & "$" & dataLocation + 6
      .Format.Line.Visible = msoTrue
      .Format.Line.Weight = 0.25
      .Format.Line.ForeColor.RGB = RGB(0, 0, 0)
  End With

 

[Domenic]

Try the following . . .

With ThisWorkbook.Sheets(sht).ChartObjects("trend_" & shp).Chart.FullSeriesCollection(1)

Hope this helps!

 

[KillGorack]

Try the following . . .

With ThisWorkbook.Sheets(sht).ChartObjects("trend_" & shp).Chart.FullSeriesCollection(1)

Hope this helps!

Perfect yes. Thank you I also have to color bars one at a time. I will try to use the above to do that as well..

 

[Domenic]

You're very welcome, glad I could help.

Cheers!