BeforePrint

[saxon25]

Hi just wondering if any one can help i have a beforeprint to check the form has been completed correctly before printing and a Msg box that askes if it has printed out ok.

the question i have is can i stop the msgbox showing unless the form is completed as i have a yes and no option if you click yes it saves the file to PDF and clears the form and being this pops up after showing the error before print there is a risk of someone pressing yes and resetting the form.

Sub PrintScreen()
ActiveSheet.PageSetup.CenterFooter = Format(Now, "DD MMMM YYYY - HH:MM")
ActiveSheet.PrintOut

Dim AnswerYes As String
Dim AnswerNo As String

AnswerYes = MsgBox("Has the document printed out ok? - if No fix the problem and try again.", vbQuestion + vbYesNo, "Document Printing")
If Answer = vbNo Then MsgBox "Please rectify the problem and print again", vbInformation, "Not Printed Out"
 
 If AnswerYes = vbYes Then Call Clearform

End Sub

 

[Domenic]

First, place the following code in the code module for ThisWorkbook (Visual Basic Editor >> View >> Project Explorer >> right-click ThisWorkbook >> select View Code)...

Option Explicit

Dim m_allowPrinting As Boolean

Public Property Let allowPrinting(ByVal v As Boolean)
    m_allowPrinting = v
End Property

Public Property Get allowPrinting() As Boolean
    allowPrinting = m_allowPrinting
End Property

Private Sub Workbook_BeforePrint(Cancel As Boolean)
    If Not m_allowPrinting Then
        Cancel = True
        MsgBox "Please print using the macro!", vbExclamation
        Exit Sub
    End If
End Sub

Then place the following code in a regular module (Visual Basic Editor >> Insert >> Module)...

Option Explicit

Sub PrintScreen()

    ThisWorkbook.allowPrinting = True

    ActiveSheet.PageSetup.CenterFooter = Format(Now, "DD MMMM YYYY - HH:MM")
    ActiveSheet.PrintOut
    
    ThisWorkbook.allowPrinting = False
    
    If MsgBox("Has the document printed out ok? - if No fix the problem and try again.", vbQuestion + vbYesNo, "Document Printing") = vbYes Then
        Call Clearform
    Else
        MsgBox "Please rectify the problem and print again", vbInformation, "Not Printed Out"
    End If

End Sub

Hope this helps!

 

[saxon25]

Hi Domenic thanks for your reply i will give this a go later on today