AutoFill syntax probleem

[LucB]

Hallo Excellers,

Graag uw hulp.

Option Explicit
Private Sub CommandButton1_Click()
    Dim i      As Long
    ActiveWorkbook.Sheets("Invoer").Activate
    Range("A3").Select
    
    i = Cells(Rows.Count, "A").End(xlUp).Row
    '3 OptionButtons in een Frame in een UserForm
    If OptionButton1 = True Then
        ActiveCell.Offset(0, 6).Value = "1"
    ElseIf OptionButton2 = True Then
        ActiveCell.Offset(0, 6).Value = "2"
    ElseIf OptionButton3 = True Then
        ActiveCell.Offset(0, 6).Value = "0"
    End If
    
    'volgende regel geeft Fout 1004
    'Gewenst: Als Cells(0, 6) een 0,1 of 2 bevat
    'dat deze naar beneden wordt doorgevoerd
    'voor zover kolom A waarden bevat.
    'Graag uw hulp bij de juiste syntax
    
    Cells(0, 6).AutoFill _
            Destination:=Range(Cells(i, 6))
End Sub

 

[erik.van.geit]

Dag, LucB,

Cells(0, 6) bestaat niet, want rij 0 bestaat niet
bedoelde je ActiveCell.Offset(0, 6) ?

beste groeten,
Erik

 

[erik.van.geit]

toch nog even meer in detail gekeken
je vroeg eigenlijk nog wat meer hulp

Option Explicit

Private Sub CommandButton1_Click()
    Dim i      As Long
    Dim v      As Integer
    ActiveWorkbook.Sheets("Invoer").Activate
    Range("A3").Select
    
    i = Cells(Rows.Count, "A").End(xlUp).Row
With ActiveCell.Offset(0, 6)
    '3 OptionButtons in een Frame in een UserForm
    If OptionButton1 = True Then
        .Value = "1"
    ElseIf OptionButton2 = True Then
        .Value = "2"
    ElseIf OptionButton3 = True Then
        .Value = "0"
    End If
    
    .AutoFill Destination:=Range(.Cells(1, 1), Cells(i, .Column))
End With
End Sub

Activate & Autofill zijn processen die de runtime verhogen
daarom lijkt dit me beter

Option Explicit

Private Sub CommandButton1_Click()
Dim i     As Long
Dim v     As Integer
Dim WS    As Worksheet
Dim cell  As Range

Set WS = ActiveWorkbook.Sheets("Invoer")
Set cell = WS.Range("A3")
 
        If OptionButton1 = True Then
            v = "1"
        ElseIf OptionButton2 = True Then
            v = "2"
        ElseIf OptionButton3 = True Then
            v = "0"
        End If

i = WS.Cells(Rows.Count, "A").End(xlUp).Row
WS.Range(cell.Offset(0, 6), WS.Cells(i, cell.Column + 6)) = v

End Sub

best regards,
Erik

 

[LucB]

Hallo Erik,

Dat bedoeld ik inderdaad,
maar de foutmelding blijft.


Luc

 

[LucB]

Erik,

Het bovenstaande slaat niet op je laatste code.
Ik ga je laatste voorstel even toepassen.
Kom later terug.

Vooreerst mijn vriedelijke dank.

 

[LucB]

Hallo Erik,

Het werkt fantastisch en razend snel.

"O wie lieblich ist der Anblick ... "

Heel hartelijk dank.

Luc

 

[erik.van.geit]

Luc,
vriendelijke man ben jij
en een mondje Duits als toemaatje ...
waar komt dit vers uit
"O wie lieblich ist der Anblick ... "
?
fijne dag verder!
Erik

 

[LucB]

Uit de Jahreszeiten van Haydn.(Sopraan solo)

Groet
Luc