Auto Fill in table 2 (meeting planner) if I key in info in table 1

[AngSP]

Hi all,

What will be the formula if I key in information in table 1 and it auto appear in the table 2 (meeting planner) above. Thank you.

Is it combination of V-Lookup + H-Lookup? I was unable to set the formula. Kindly need expert to teach me. Thanks a lot.

 

[Alex Blakenburg]

Is this what you had in mind ?

20230207 2 Way lookup AngSP.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L
1
2	Meeting	1/02/2023	2/02/2023	3/02/2023	4/02/2023	5/02/2023	6/02/2023	7/02/2023	8/02/2023	9/02/2023	10/02/2023
3	Apple			5PM
4	Boat									1PM
5	Cat			12PM
6
7
14
15
16	Meeting	Data	Time
17	Apple	3/02/2023	5PM
18	Boat	9/02/2023	1PM
19	Cat	3/02/2023	12PM
20
Data

Cell Formulas
Range	Formula
B3:K5	B3	=XLOOKUP(1,(Table1[Meeting]=$A3)*(Table1[Data]=B$2),Table1[Time],"")

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
B3:K5	Expression	=B3<>""	text	NO

 

[AngSP]

Thank you, Alex.

When, I tried the formula, I was unable to reflect on it.
Let me show the exact excel I wanted to do. I am not sure, if there is any formula that can perform this function or, is there any simple way to do it.
I only have a little knowledge on this excel.

My requirement is

(1) When I key information in "Info" tab, the information will be reflected on the other tab (eg Feb, March, April, May.... etc)
eg. Dry's meeting scheduled on 7-Feb and 2-Mar, once I keyed the info in "Info" tab, then the name, date and time automatically reflect on tab Feb and tab March.

(2) Or do you have any other idea or better way to work on this?

Or my requirement is too much?

Thank you.

 

[Alex Blakenburg]

Do you need a sheet for each month ?
How about 1 sheet and a drop down to select the month ?

20230207 2 Way lookup AngSP.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W	X	Y	Z	AA	AB	AC	AD	AE	AF	AG
1
2		February
3
4		Meeting	1-Feb	2-Feb	3-Feb	4-Feb	5-Feb	6-Feb	7-Feb	8-Feb	9-Feb	10-Feb	11-Feb	12-Feb	13-Feb	14-Feb	15-Feb	16-Feb	17-Feb	18-Feb	19-Feb	20-Feb	21-Feb	22-Feb	23-Feb	24-Feb	25-Feb	26-Feb	27-Feb	28-Feb
5		Apple			5PM
6		Boat									1PM
7		Cat			12PM
8		Dry
Calendar Month

Cell Formulas
Range	Formula
C4:AD4	C4	=B2+SEQUENCE(,DAY(EOMONTH(B2,0)),0,1)
B5:B8	B5	=SORT(FILTER(Table1[Meeting],(Table1[Data]>=B2)*(Table1[Data]<=EOMONTH(B2,0)),""))
C5:AG7	C5	=XLOOKUP(1,(Table1[Meeting]=$B5)*(Table1[Data]=C$4),Table1[Time],"")
Dynamic array formulas.

Cells with Conditional Formatting
Cell	Condition		Cell Format	Stop If True
C5:AG7	Expression	=C5<>""	text	NO

Cells with Data Validation
Cell	Allow	Criteria
B2	List	=Info!$E$3:$E$14

20230207 2 Way lookup AngSP.xlsx
	A	B	C	D	E
1	Table1
2	Meeting	Data	Time		Months
3	Apple	3/02/2023	5PM		January
4	Boat	9/02/2023	1PM		February
5	Cat	3/02/2023	12PM		March
6	Dry	6/02/2023	11AM		April
7	Apple	15/03/2023	10AM		May
8					June
9					July
10					August
11					September
12					October
13					November
14					December
15
Info

 

[AngSP]

Hi Alex,

Thanks alot. But, I need some time to study the formula.