Auto date entry

[ExcelRoy]

Hi,

I have the following formula which date stamps into column D when something is entered into column E

is there a way to delete the entry if the cell in E has been deleted

Many thanks

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rInt As Range
    Dim rCell As Range
    Dim tCell As Range

    Set rInt = Intersect(Target, Range("E:E"))
    If Not rInt Is Nothing Then
        For Each rCell In rInt
            Set tCell = rCell.Offset(0, -1)
            If IsEmpty(tCell) Then
                tCell = Now
                tCell.NumberFormat = "dd/mm/yyyy"
            End If
        Next
    End If
End Sub

 

[Joe4]

Here is one way:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rInt As Range
    Dim rCell As Range
    Dim tCell As Range

    Set rInt = Intersect(Target, Range("E:E"))
    If Not rInt Is Nothing Then
        For Each rCell In rInt
            Set tCell = rCell.Offset(0, -1)
            If rCell <> "" Then
                If IsEmpty(tCell) Then
                    tCell = Now
                    tCell.NumberFormat = "dd/mm/yyyy"
                End If
            Else
                tCell.ClearContents
            End If
        Next
    End If
End Sub

 

[ExcelRoy]

That's perfect thanks Joe4