Auda con codigo.

[UliCs]

Hola a todos.

hice este codigo. la verdad no soy bueno en esto pero lo intento.
quiero copiar un rango y peganlo. hasta hay lo hace bien. el problema es cuando quiero pegarlo en otra hoja "me marca un error" o quiero copiar los datos de otro libro "no puedo pasar a otro libro", como puedo hacer esto.
espero me puedan ayudar.

Private Sub Input_Nvo()
Dim R1 As Range
Dim R2 As Range

Set R1 = Application.InputBox("Selecciona el Rango a Copiar. " & Chr(10) & Chr(10) & " WID - Comentarios", "Copiar", Type:=8)
R1.Select
Set R2 = Application.InputBox("Selecciona la celda Destino. " & Chr(10) & " WID - Comentarios", "Destino", Type:=8)
R1.Copy
ActiveSheet.Paste Destination:=R2
R2.Select

Application.CutCopyMode = False

End Sub

Gracias anticipadas. y saludos.

<div_prefs id="div_prefs"></div_prefs><div_prefs id="div_prefs"></div_prefs><div_prefs id="div_prefs"></div_prefs>

 

[Jerry Sullivan]

Hola UliCs,

Lo siento que no hablo español, pero con la ayuda de Google Translate, voy a tratar de ayudarle.

El código no funciona porque se necesita para activar la celda de destino antes de pegar.

¿Hay alguna razón que usted está usando el comando InputBox lugar de una lista desplegable de validación? Si el usuario debe escoger o entrar en la fuente y el destino celular, entonces parece que sería más fácil de usar un manual de copia (Ctrl-C) y Pegar (Ctrl-V).

Si usted explica su propósito entonces tal vez puede ayudar a hacer esto mejor.

Un cordial saludo,

 

[Greg Truby]

Hola Ulics,

Espero que la presente le encuentre bien. Perdóname por haber tardado tanto en volver a MrExcel pero tengo más de un mes de no tener mucho tiempo libre.

No sé si usted ya ha resuelto el problema arriba o no pero el código abajo sí me permite copiar y pegar de una hoja a otra y también de un cuaderno a otro.

Espero que le ayude y saludos,

Private Sub Input_Nvo_2()
 
    Const c_strMensFuente As String = "Selecciona el Rango a Copiar. " & vbCr & vbCr _
                                  & " WID - Comentarios"
 
    Const c_strMensDestino As String = "Selecciona la celda Destino. " & vbCr & vbCr _
                                  & " WID - Comentarios"
 
    Dim rngFuente As Excel.Range, rngDestino As Excel.Range
 
    On Error Resume Next 
    Set rngFuente = Application.InputBox(c_strMensFuente, "Copiar", Type:=8)
    Set rngDestino = Application.InputBox(c_strMensDestino, "Destino", Type:=8)
    On Error GoTo 0
 
    If Not rngFuente Is Nothing _
    And Not rngDestino Is Nothing Then
 
        rngFuente.Copy rngDestino
 
        rngDestino.Parent.Activate
        rngDestino.Select
 
    End If
 
    Application.CutCopyMode = False
End Sub