ATOCODES

[schardt679]

ATOCODES returns an array of individual character codes from a one dimensional array of text strings with an option to remove non-printing characters.
Horizontal ranges spill down rows and vertical ranges spill across columns.
Calls ATOCHARS.
Other functions on minisheet: AFORMULATEXT.

=LAMBDA(Array,Remove_Nonprinting,
      LET(Arr, Array,
          RemNon?, Remove_Nonprinting,
          A1D?, AONEDIM(Arr),
          AScan, AND(A1D?<>{"H","V"}),
          Horiz?, A1D?="H",
          NonScan, AND(RemNon?<>{1,0}),
          NonMSG, "Nonprinting=1,0",
          ERRORS, IFS(AScan, A1D?,  NonScan, NonMSG,  1, 0),
          UChars, ATOCHARS(Arr, RemNon?),
          UCodes, UNICODE(UChars),
          Result, IF((UChars="")+(ISERROR(UChars)), UChars, UCodes),
          Return, IF(ERRORS<>0, ERRORS, Result),
          Return
      )
 )

LAMBDA Examples.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P
1		ATOCODES
2
3		Text		Result
4		Hello		160	72	101	108	108	111	32	32	32	32
5
6		There!		84	104	101	114	101	127	33
7
8		#N/A		#N/A
9		I am 27.		73	32	97	109	32	32	32	32	32	50	55	46
10
11		Data is a vertical array
12		Result spills horizontally
13		Nonprinting characters aren't removed
14		Formula in cell D4☛ =ATOCODES(B4:B9,)
15
16
17
18		Text		Result
19		Hello		72	101	108	108	111
20		There!		84	104	101	114	101	33
21
22		#N/A		#N/A
23		I am 27.		73	32	97	109	32	50	55	46
24
25		Data is a vertical array
26		Result spills horizontally
27		Nonprinting characters aren't removed
28		Formula in cell D19☛ =ATOCODES(B19:B23, 1)
29
30
31
32		Text	Hello	There!		#N/A	I am 27.
33
34		Result	160	84		#N/A	73
35			72	104			32
36			101	101			97
37			108	114			109
38			108	101			32
39			111	127			32
40			32	33			32
41			32				32
42			32				32
43			32				50
44							55
45							46
46
47		Data is a horizontal array
48		Result spills vertically
49		Nonprinting characters aren't removed
50		Formula in cell C34☛ =ATOCODES(C32:G32,)
51
ATOCODES

Cell Formulas
Range	Formula
D4:O9	D4	=ATOCODES(B4:B9,)
B14	B14	=AFORMULATEXT(D4)
D19:K23	D19	=ATOCODES(B19:B23, 1)
B28	B28	=AFORMULATEXT(D19)
F32	F32	=NA()
C34:G45	C34	=ATOCODES(C32:G32,)
B50	B50	=AFORMULATEXT(C34)
Dynamic array formulas.

 

[schardt679]

ATOCODES has been updated. Since the function calls ATOCHARS which calls ATRIM (removes extra occurrences of a specified delimiter and nonprinting characters listed in CLEAN), an optional Delimiter argument was added. By default, it is a space.

ATOCODES returns an array of individual character codes from a one dimensional array of text strings with an option to remove extra occurrences of a specified delimiter and non-printing characters.

Horizontal ranges spill down rows and vertical ranges spill across columns.
Calls ATOCHARS.
Other functions on minisheet: AFORMULATEXT.

Screen Tip/ Comment: =ATOCODES(Array☛ range to return individual character codes, [Clean_Data]☛ 1=remove extra delimiters and non-printing characters listed in CLEAN; 0/=don't, [Delimiter]☛ separator; =" ") ⁂[]= optional; =default; =omit

The syntax is slightly different: ATOCODES(Array,[Clean_Data],[Delimiter])

Array: Required. Array to return individual character codes.
[Remove_Nonprinting] is now [Clean_Data]: Optional. 1☛ remove extra delimiters and non-printing characters listed in CLEAN; 0 or ignored☛ don't remove
[Delimiter]: Optional. Value separator(s); ignored☛ space. Can be multiple separators but the row/ column count must match array.

If {Clean_Data] is omitted, [Delimiter] is irrelevant.

=LAMBDA(Array,[Clean_Data],[Delimiter],
      LET(Arr, Array,          Clean?, Clean_Data,          Del, Delimiter,
             UChars, ATOCHARS(Arr, Clean?, Del),          UCodes, UNICODE(UChars),
             Result, IFERROR(UCodes,  UChars),          Return, IF(LEN(UChars)>1, UChars,  Result),
             Return
      )
  )

LAMBDA Examples.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S
54		ATOCODES
55
56		Text		Clean_Data:	1		Result
57		03/22///21		Delimiter:	/		48	51	47	50	50	47	50	49
58		#VALUE!					#VALUE!
59		03//22///21					48	51	47	50	50	47	50	49
60		03//23/21					48	51	47	50	51	47	50	49	32
61
62		03/23/21					48	51	47	50	51	47	50	49
63		03/24/21					52	52	50	55	57
64
65		Data is a vertical array --> result spills horizontally
66		Nonprinting characters and extra delimiters are removed
67		Delimiter is slash
68		Formula in cell G57☛ =ATOCODES(B57:B63, E56, E57)
69
70
71
72		Text		Clean_Data:	1		Result
73		1, , , 2, 3, , 4		Delimiter:	,		49	44	32	50	44	32	51	44	32	32	52
74		A;;B;C;;;D			;		65	59	66	59	67	59	68
75		A1|A2|||B||C			|		65	49	124	65	50	124	66	124	67
76		D||E|||F||||G			||		68	124	124	69	124	124	124	70	124	124	71
77
78		Data is a vertical array --> result spills horizontally
79		Nonprinting characters and extra delimiters are removed
80		There are multiple delimiters.
81		Formula in cell G73☛ =ATOCODES(B73:B76, E72, E73:E76)
82
ATOCODES

Cell Formulas
Range	Formula
G57:O63	G57	=ATOCODES(B57:B63, E56, E57)
B58	B58	=1+"A"
B68	B68	=AFORMULATEXT(G57)
G73:Q76	G73	=ATOCODES(B73:B76, E72, E73:E76)
B81	B81	=AFORMULATEXT(G73)
Dynamic array formulas.