Assistance with a excel formula

[Kthom019]

I need the below formula to input the cost in column A based on the start month, in column C, and the number of periods in column B.

the formula in column D (m1) = =IFERROR(INDEX($A236,MATCH($C236,D$235,0)),0)
the formula in column E (m2) = =IFERROR(IF(D243=0,(INDEX($A243,MATCH($C243,E$235,0))/$B243),D243),0)

I do not want to exceed the total in column A. I hope I explained that correctly.

			m1	m2	m3	m4	m5	m6	m7	m8	m9	m10	m11	m12
29,647	2​	m3	$ -	$ -	$ 14,824	$ 14,824	$ 14,824	$ 14,824
3,330	5​	m5	$ -	$ -	$ -	$ -	$ 666	$ 666
2,191	3​	m2	$ -	$ 2,191	$ 2,191	$ 2,191	$ 2,191	$ 2,191
978	4​	m4	$ -	$ -	$ -	$ 245	$ 245	$ 245
			$ -	$ 2,191	$ 17,015	$ 17,259	$ 17,925	$ 17,925	$ -	$ -	$ -	$ -	$ -	$ -

 

[Fluff]

How about

+Fluff v2.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1				m1	m2	m3	m4	m5	m6	m7	m8	m9	m10	m11	m12
2	29,648	2	m3			14,824	14,824	14,824	14,824
3	1,332	5	m5					666	666
4	6,573	3	m2		2,191	2,191	2,191	2,191	2,191
5	735	4	m4				245	245	245
Master

Cell Formulas
Range	Formula
A2:A5	A2	=SUM(INDEX(D2:O2,MATCH(C2,$D$1:$O$1,0)):INDEX(D2:O2,MATCH(C2,$D$1:$O$1,0)+B2-1))

 

[Kthom019]

=SUM(INDEX(D2:O2,MATCH(C2,$D$1:$O$1,0)):INDEX(D2:O2,MATCH(C2,$D$1:$O$1,0)+B2-1))

Column should not have a formula. I may not have explained correctly then.

the formula is needed in columns D:O
I want to split the cost, which is column A, across the months, based on the start period in Column C, Column B is # of months for the splits.
(row 2 is saying split the amount in column A, across 2 months, starting in month 3 (M3)

 

[Fluff]

Then how about

+Fluff v2.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1				m1	m2	m3	m4	m5	m6	m7	m8	m9	m10	m11	m12
2	29,647	2	m3	0	0	0	14823.5	14823.5	0	0	0	0	0	0	0
3	3,330	5	m5	0	0	0	0	0	666	666	666	666	666	0	0
4	2,191	3	m2	0	0	730.3333	730.3333	730.3333	0	0	0	0	0	0	0
5	978	4	m4	0	0	0	0	244.5	244.5	244.5	244.5	0	0	0	0
6
Master

Cell Formulas
Range	Formula
D2:O5	D2	=IF(AND(COLUMNS($D$1:D$1)>MATCH($C2,$D$1:$O$1,0),COLUMNS($D$1:D$1)<=MATCH($C2,$D$1:$O$1,0)+$B2),$A2/$B2,0)

 

[Kthom019]

The costs are not starting in the correct columns. Example, in row 2, the cost should start in column 5.

 

[Fluff]

Oops, put the = in the wrong place, it should be

=IF(AND(COLUMNS($D$1:D$1)>=MATCH($C2,$D$1:$O$1,0),COLUMNS($D$1:D$1)<MATCH($C2,$D$1:$O$1,0)+$B2),$A2/$B2,0)

 

[Kthom019]

Oops, put the = in the wrong place, it should be

=IF(AND(COLUMNS($D$1:D$1)>=MATCH($C2,$D$1:$O$1,0),COLUMNS($D$1:D$1)<MATCH($C2,$D$1:$O$1,0)+$B2),$A2/$B2,0)

This is absolutely perfect thank you so much. I know my explanation was not was not perfect at first, my bad. I was typing while in a meeting to create a template and you saved the day; much appreciated.

 

[Fluff]

You're welcome & thanks for the feedback.