ASPLIT

[Xlambda]

ASPLIT splits a column array by delimiter, calls AUNQSRT. Proves the point of how simple a complicated task could be with the help of other lambda tools.

=LAMBDA(ar,d,
    LET(a,TRIM(ar),
        s,SEQUENCE(,MAX(LEN(a))),
        x,IFERROR(SEARCH(d,d&a,s),""),
        y,IFERROR(SEARCH(d,a&d,s),""),
        m,AUNQSRT(x,),n,AUNQSRT(y,),
        z,IFERROR(TRIM(MID(a,m,n-m)),""),
        IF(ISERROR(--z),z,--z)
    )
)

LAMBDA 5.0.xlsx
	A	B	C	D	E	F	G	H	I
1	r66, , -1.86,.73			r66		-1.86	0.73
2	,a ,23, a , b23				a	23	a	b23
3	5,5,4,5			5	5	4	5
4	%, &5, 2,wow			%	&5	2	wow
5
6				r66	-1.86	0.73
7				a	23	a	b23
8				5	5	4	5
9				%	&5	2	wow
10
11				r66
12				a	a	b23
13
14				%	&5	wow
15
16				-1.86	0.73
17				23
18				5	5	4	5
19				2
20
21	set↓in asc. order
22
23	2 -1.5 .6			-1.5	0.6	2
24	.are ,you ·good			,you	.are	·good
25	·are .you ,sure			,sure	.you	·are
26	0 !% a			0	!%	a
27
28
29	dbl;transpose	will;do;the trick		dbl	transpose
30				will	do	the trick
31
ASPLIT post

Cell Formulas
Range	Formula
D1:H4	D1	=ASPLIT(A1:A4,",")
D6:G9	D6	=AFILTER(D1#,,)
D11:F14	D11	=AFILTER(D1#,-1,)
D16:G19	D16	=AFILTER(D1#,1,)
D23:F26	D23	=AUNQSRT(ASPLIT(A23:A26," "),1)
D29:F30	D29	=ASPLIT(TRANSPOSE(A29:B29),";")
Dynamic array formulas.