ASCAN

[Xlambda]

ASCAN, Array SCAN, 3 in 1 function, SCAN by row, by column, by array. This is my take of tboulden's SCANBYROW/BYCOL.
Uses only new!! SCAN lambda helper function, no need of byrow,bycol,makearray, or lambda as arguments.

=LAMBDA(a,[d],
    LET(y,IF(d=1,TRANSPOSE(a),a),s,SCAN(0,y,LAMBDA(v,a,v+a)),r,ROWS(s),c,COLUMNS(s),sr,SEQUENCE(r)-1,
       x,s-IF(d,IFERROR(INDEX(INDEX(s,,c),sr)*sr^0,0),0),
       IF(d=1,TRANSPOSE(x),x)
   )
)

LAMBDA 1.1.3.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1						d,omitted (by array)					d,-1 (by rows)					d,1 (by clms)
2	sample 1			a		=ASCAN(A3:D6)					=ASCAN(A3:D6,-1)					=ASCAN(A3:D6,1)
3	1	2	3	4		1	3	6	10		1	3	6	10		1	2	3	4
4	5	6	7	8		15	21	28	36		5	11	18	26		6	8	10	12
5	9	10	11	12		45	55	66	78		9	19	30	42		15	18	21	24
6	13	14	15	16		91	105	120	136		13	27	42	58		28	32	36	40
7
8						d,omitted (by array)					d,-1 (by rows)					d,1 (by clms)
9	sample 2			a		=ASCAN(A10#)					=ASCAN(A10#,-1)					=ASCAN(A10#,1)
10	1	2	3	4		1	3	6	10		1	3	6	10		1	2	3	4
11	5	6	7	8		15	21	28	36		5	11	18	26		6	8	10	12
12	9	10	11	12		45	55	66	78		9	19	30	42		15	18	21	24
13	13	14	15	16		91	105	120	136		13	27	42	58		28	32	36	40
14	17	18	19	20		153	171	190	210		17	35	54	74		45	50	55	60
15	21	22	23	24		231	253	276	300		21	43	66	90		66	72	78	84
16
17	Note: Did not set an extra argument for any kind of "initial value", since the only thing it does is too simple,
18	adds a constant value to the final outcome , like in 10+ASCAN(a)
19
ASCAN post

Cell Formulas
Range	Formula
F2,P9,K9,F9,P2,K2	F2	=FORMULATEXT(F3)
F3:I6	F3	=ASCAN(A3:D6)
K3:N6	K3	=ASCAN(A3:D6,-1)
P3:S6	P3	=ASCAN(A3:D6,1)
A10:D15	A10	=SEQUENCE(6,4)
F10:I15	F10	=ASCAN(A10#)
K10:N15	K10	=ASCAN(A10#,-1)
P10:S15	P10	=ASCAN(A10#,1)
Dynamic array formulas.

 

[Xlambda]

Second draft, shorter. The concept of SCAN by row or by col is extremely simple. We SCAN the whole array with whatever operation and then we amend the result with the values that keep first row or first column intact.

=LAMBDA(a,[d],
    LET(y,IF(d=1,TRANSPOSE(a),a),s,SCAN(0,y,LAMBDA(v,a,v+a)),
       x,s-IF(d,INDEX(s,,1)-INDEX(y,,1)),
       IF(d=1,TRANSPOSE(x),x)
    )
)

LAMBDA 1.1.3.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1	same outcome as before					d,omitted (by array)					d,-1 (by rows)					d,1 (by clms)
2	sample 1			a		=ASCAN(A3:D6)					=ASCAN(A3:D6,-1)					=ASCAN(A3:D6,1)
3	1	2	3	4		1	3	6	10		1	3	6	10		1	2	3	4
4	5	6	7	8		15	21	28	36		5	11	18	26		6	8	10	12
5	9	10	11	12		45	55	66	78		9	19	30	42		15	18	21	24
6	13	14	15	16		91	105	120	136		13	27	42	58		28	32	36	40
7
8						d,omitted (by array)					d,-1 (by rows)					d,1 (by clms)
9	sample 2			a		=ASCAN(A10#)					=ASCAN(A10#,-1)					=ASCAN(A10#,1)
10	1	2	3	4		1	3	6	10		1	3	6	10		1	2	3	4
11	5	6	7	8		15	21	28	36		5	11	18	26		6	8	10	12
12	9	10	11	12		45	55	66	78		9	19	30	42		15	18	21	24
13	13	14	15	16		91	105	120	136		13	27	42	58		28	32	36	40
14	17	18	19	20		153	171	190	210		17	35	54	74		45	50	55	60
15	21	22	23	24		231	253	276	300		21	43	66	90		66	72	78	84
16
ASCAN post

Cell Formulas
Range	Formula
F2,P9,K9,F9,P2,K2	F2	=FORMULATEXT(F3)
F3:I6	F3	=ASCAN(A3:D6)
K3:N6	K3	=ASCAN(A3:D6,-1)
P3:S6	P3	=ASCAN(A3:D6,1)
A10:D15	A10	=SEQUENCE(6,4)
F10:I15	F10	=ASCAN(A10#)
K10:N15	K10	=ASCAN(A10#,-1)
P10:S15	P10	=ASCAN(A10#,1)
Dynamic array formulas.

 

[Xlambda]

Third draft. More versatility for real life scenarios, can handle blanks, null strings, text, errors, d argument wrong input.

=LAMBDA(a,[d],
    LET(n,ISNUMBER(a),r,IF(n,a,0),o,IF(d,d^0*SIGN(d),0),y,IF(o=1,TRANSPOSE(r),r),
      s,SCAN(0,y,LAMBDA(v,a,v+a)),x,s-IF(o,INDEX(s,,1)-INDEX(y,,1)),
      IF(n,IF(o=1,TRANSPOSE(x),x),a)
    )
)

LAMBDA 1.1.3.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
1						d,omitted (by array)					d,-1 (by rows)					d,1 (by clms)
2	sample					=ASCAN(A3:D7)					=ASCAN(A3:D7,-1)					=ASCAN(A3:D7,1)
3	1	a	3	4		1	a	4	8		1	a	4	8		1	a	3	4
4	5	6	7	8		13	19	26	34		5	11	18	26		6	6	10	12
5	9	10	11	#N/A		43	53	64	#N/A		9	19	30	#N/A		15	16	21	#N/A
6	13		15	16		77		92	108		13		28	44		28		36	28
7	17	18		20		125	143	0	163		17	35	0	55		45	34	0	48
8
9						Note:	Blanks will be returned 0's because a blnk is a 0 and a null string at the same time.
10		null string B6=""					Null strings will remain intact as any other text value.
11		blank					The functions works only with the numeric layer, everything else returned as in the initial array
12		text
13		error				when d out of range, d <> {0,-1,1} , if d<0,d=-1, if d>0, d=1
14						d,-3 <=> d=-1					d,4 <=> d=1
15						=ASCAN(A3:D7,-3)					=ASCAN(A3:D7,4)
16						1	a	4	8		1	a	3	4
17						5	11	18	26		6	6	10	12
18						9	19	30	#N/A		15	16	21	#N/A
19						13		28	44		28		36	28
20						17	35	0	55		45	34	0	48
21
ASCAN post 3

Cell Formulas
Range	Formula
F2,K15,F15,P2,K2	F2	=FORMULATEXT(F3)
F3:I7	F3	=ASCAN(A3:D7)
K3:N7	K3	=ASCAN(A3:D7,-1)
P3:S7	P3	=ASCAN(A3:D7,1)
D5	D5	=NA()
B6	B6	=""
F16:I20	F16	=ASCAN(A3:D7,-3)
K16:N20	K16	=ASCAN(A3:D7,4)
Dynamic array formulas.

 

[Xlambda]

Following first concept (we use only SCAN for the whole array, and we amend the result to keep the first row or first clm of initial array intact) , this is how it looks for appending by row.
The trick using this concept in general is finding the proper "amending" formula.
Since I do not see any practicability in real life, did not allocate a dedicated lambda function.

=LAMBDA(a,LET(s,SCAN("",A3:D5,LAMBDA(v,a,v&a)),RIGHT(s,LEN(s)-LEN(INDEX(s,,1))+LEN(INDEX(a,,1)))))

LAMBDA 1.1.3.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1
2	sample			a		=LAMBDA(a,LET(s,SCAN("",A3:D5,LAMBDA(v,a,v&a)),RIGHT(s,LEN(s)-LEN(INDEX(s,,1))+LEN(INDEX(a,,1)))))(A3:D5)
3	a	b	c	d		a	ab	abc	abcd
4	x	2	3	4		x	x2	x23	x234
5	rt	67	89	67		rt	rt67	rt6789	rt678967
6
ASCAN post 4

Cell Formulas
Range	Formula
F2	F2	=FORMULATEXT(F3)
F3:I5	F3	=LAMBDA(a,LET(s,SCAN("",A3:D5,LAMBDA(v,a,v&a)),RIGHT(s,LEN(s)-LEN(INDEX(s,,1))+LEN(INDEX(a,,1)))))(A3:D5)
Dynamic array formulas.

 

[Xlambda]

If I said no lambda, then should be a formula, a simple let:
=LET(a,A3:D5,s,SCAN("",a,LAMBDA(v,a,v&a)),RIGHT(s,LEN(s)-LEN(INDEX(s,,1))+LEN(INDEX(a,,1))))

LAMBDA 1.1.3.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1
2	sample			a		=LET(a,A3:D5,s,SCAN("",a,LAMBDA(v,a,v&a)),RIGHT(s,LEN(s)-LEN(INDEX(s,,1))+LEN(INDEX(a,,1))))
3	a	b	c	d		a	ab	abc	abcd
4	x	2	3	4		x	x2	x23	x234
5	rt	67	89	67		rt	rt67	rt6789	rt678967
6
ASCAN post 4

Cell Formulas
Range	Formula
F2	F2	=FORMULATEXT(F3)
F3:I5	F3	=LET(a,A3:D5,s,SCAN("",a,LAMBDA(v,a,v&a)),RIGHT(s,LEN(s)-LEN(INDEX(s,,1))+LEN(INDEX(a,,1))))
Dynamic array formulas.

 

[Xlambda]

Second concept. Does not require a lambda, is a simple formula that we can write anywhere according to context.
Uses SCAN embedded in MAKEARRAY (similar concept in AMORTIZE)

LAMBDA 1.1.3.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1						adding by row
2	sample array 5x4					=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN(0,x,LAMBDA(v,a,v+a)),INDEX(s,1,c))))
3	1	2	3	4		1	3	6	10
4	5	6	7	8		5	11	18	26
5	9	10	11	12		9	19	30	42
6	13	14	15	16		13	27	42	58
7	17	18	19	20		17	35	54	74
8
9						appending by row
10						=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN("",x,LAMBDA(v,a,v&a)),INDEX(s,1,c))))
11						1	12	123	1234
12						5	56	567	5678
13						9	910	91011	9101112
14						13	1314	131415	13141516
15						17	1718	171819	17181920
16
17						multiplication by row
18						=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN(1,x,LAMBDA(v,a,a*v)),INDEX(s,1,c))))
19						1	2	6	24
20						5	30	210	1680
21						9	90	990	11880
22						13	182	2730	43680
23						17	306	5814	116280
24
25						division by row
26						=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN(1,x,LAMBDA(v,a,a/v)),INDEX(s,1,c))))
27						1	2	1.5	2.666667
28						5	1.2	5.833333	1.371429
29						9	1.111111	9.9	1.212121
30						13	1.076923	13.92857	1.148718
31						17	1.058824	17.94444	1.114551
32
ASCAN post 5

Cell Formulas
Range	Formula
F2,F26,F18,F10	F2	=FORMULATEXT(F3)
A3:D7	A3	=SEQUENCE(5,4)
F3:I7	F3	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN(0,x,LAMBDA(v,a,v+a)),INDEX(s,1,c))))
F11:I15	F11	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN("",x,LAMBDA(v,a,v&a)),INDEX(s,1,c))))
F19:I23	F19	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN(1,x,LAMBDA(v,a,a*v)),INDEX(s,1,c))))
F27:I31	F27	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,r,),s,SCAN(1,x,LAMBDA(v,a,a/v)),INDEX(s,1,c))))
Dynamic array formulas.

 

[Xlambda]

Humble Conclusion!!
I think that these new lambda helper functions are so intrinsic versatile and powerful that their main purpose is not to help us in lambda constructions, quite the opposite, they were created to help us in lambdas deconstruction.
I know, first instinct is, wow, I can write a lambda doing this. If we'll write a lambda for every construction that these new functions are capable of, soon, our name manager will be oversaturated with a tone of lambdas, variables, fancy arguments, doing nothing, never used in real life, never embraced by other users, doing stuff that a simple short formula can do. It's so unproductive as gluing lego pieces. And these exercises here are a proof of how simple is to omit a lambda. Even if these examples have no use in real life, they help us understand how simple and versatile these constructions can be. We are witnessing a paradigm shift. My 2 cents. Sorry for the long talk. To end on a funny note, ASCAN will survive, running totals are practical. ?✌

LAMBDA 1.1.3.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1						adding by col
2	sample array 5x4					=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN(0,x,LAMBDA(v,a,v+a)),INDEX(s,r,1))))
3	1	2	3	4		1	2	3	4
4	5	6	7	8		6	8	10	12
5	9	10	11	12		15	18	21	24
6	13	14	15	16		28	32	36	40
7	17	18	19	20		45	50	55	60
8
9						appending by col
10						=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN("",x,LAMBDA(v,a,v&a)),INDEX(s,r,1))))
11						1	2	3	4
12						15	26	37	48
13						159	2610	3711	4812
14						15913	261014	371115	481216
15						1591317	26101418	37111519	48121620
16
17						multiplication by col
18						=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN(1,x,LAMBDA(v,a,v*a)),INDEX(s,r,1))))
19						1	2	3	4
20						5	12	21	32
21						45	120	231	384
22						585	1680	3465	6144
23						9945	30240	65835	122880
24
25						division by col
26						=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN(1,x,LAMBDA(v,a,a/v)),INDEX(s,r,1))))
27						1	2	3	4
28						5	3	2.3333333	2
29						1.8	3.3333333	4.7142857	6
30						7.2222222	4.2	3.1818182	2.6666667
31						2.3538462	4.2857143	5.9714286	7.5
32
ASCAN post 6

Cell Formulas
Range	Formula
F2,F26,F18,F10	F2	=FORMULATEXT(F3)
A3:D7	A3	=SEQUENCE(5,4)
F3:I7	F3	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN(0,x,LAMBDA(v,a,v+a)),INDEX(s,r,1))))
F11:I15	F11	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN("",x,LAMBDA(v,a,v&a)),INDEX(s,r,1))))
F19:I23	F19	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN(1,x,LAMBDA(v,a,v*a)),INDEX(s,r,1))))
F27:I31	F27	=MAKEARRAY(5,4,LAMBDA(r,c,LET(x,INDEX(A3#,,c),s,SCAN(1,x,LAMBDA(v,a,a/v)),INDEX(s,r,1))))
Dynamic array formulas.

 

[Xlambda]

What if we want to apply various functions to each row of an array, (UNIQUE or FILTER or SORT), instead of only simple operations?
(Exactly what AFUSBYROW does without the lambda helper functions)
It's quite easy, using a trick. Since in this case, SCAN cannot return "row" arrays, as we need, we can TEXTJOIN the result of each row, in a single value, and split them afterwards.
Another argument in favor of how a simple and short lambda "formula" can replace the functionality of custom-made dedicated functions.

LAMBDA 1.1.4.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T	U	V	W
1	1. Extracting UNIQUE values of each row of an array
2
3	sample						ad				other functions
4	4	3	3	3	1	1	4				AFUSBYROW
5	2	1	1	2	7	7	5				ATEXTSPLIT
6	8	6	6	5	5	8	9
7
8	the result we are looking for:
9	=AFUSBYROW(ad,,1)							=SCAN("",SEQUENCE(3),LAMBDA(v,i,TEXTJOIN(",",,UNIQUE(INDEX(ad,i,),1))))
10	4	3	1					4,3,1
11	2	1	7	5				2,1,7,5			next step, splitting
12	8	6	5	9				8,6,5,9			=ATEXTSPLIT(H10#)
13											4	3	1
14											2	1	7	5
15											8	6	5	9
16											as we see, we get the same result
17	2. SORTing in ascending order, each row
18
19	the result we are looking for:								lambda formula
20	=AFUSBYROW(ad,,,1)								=SCAN("",SEQUENCE(3),LAMBDA(v,i,TEXTJOIN(",",,SORT(INDEX(ad,i,),,,1))))
21	1	1	3	3	3	4	4		1,1,3,3,3,4,4
22	1	1	2	2	5	7	7		1,1,2,2,5,7,7		next step, splitting
23	5	5	6	6	8	8	9		5,5,6,6,8,8,9		=ATEXTSPLIT(I21#)
24											1	1	3	3	3	4	4
25											1	1	2	2	5	7	7
26											5	5	6	6	8	8	9
27											as we see, we get the same result
28	3. SORTing in descending order, each row
29
30	the result we are looking for:								lambda formula
31	=AFUSBYROW(ad,,,-1)								=SCAN("",SEQUENCE(3),LAMBDA(v,i,TEXTJOIN(",",,SORT(INDEX(ad,i,),,-1,1))))
32	4	4	3	3	3	1	1		4,4,3,3,3,1,1
33	7	7	5	2	2	1	1		7,7,5,2,2,1,1		next step, splitting
34	9	8	8	6	6	5	5		9,8,8,6,6,5,5		=ATEXTSPLIT(I32#)
35											4	4	3	3	3	1	1
36											7	7	5	2	2	1	1
37											9	8	8	6	6	5	5
38											as we see, we get the same result
39
ASCAN post 7

Cell Formulas
Range	Formula
A9,K34,I31,A31,K23,I20,A20,K12,H9	A9	=FORMULATEXT(A10)
A10:D12	A10	=AFUSBYROW(ad,,1)
H10:H12	H10	=SCAN("",SEQUENCE(3),LAMBDA(v,i,TEXTJOIN(",",,UNIQUE(INDEX(ad,i,),1))))
K13:N15	K13	=ATEXTSPLIT(H10#)
A21:G23	A21	=AFUSBYROW(ad,,,1)
I21:I23	I21	=SCAN("",SEQUENCE(3),LAMBDA(v,i,TEXTJOIN(",",,SORT(INDEX(ad,i,),,,1))))
K24:Q26,K35:Q37	K24	=ATEXTSPLIT(I21#)
A32:G34	A32	=AFUSBYROW(ad,,,-1)
I32:I34	I32	=SCAN("",SEQUENCE(3),LAMBDA(v,i,TEXTJOIN(",",,SORT(INDEX(ad,i,),,-1,1))))
Dynamic array formulas.

Named Ranges
Name	Refers To	Cells
ad	='ASCAN post 7'!$A$4:$G$6	I32, I21, H10, A32, A21, A10

 

[tboulden]

SCAN cannot return "row" arrays, as we need, we can TEXTJOIN

A little more readable using BYROW and ARRAYTOTEXT:

LAMBDA_SCANBY.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	4	3	3	3	1	1	4
2	2	1	1	2	7	7	5
3	8	6	6	5	5	8	9
4
5									4, 3, 1	=BYROW(A1:G3, LAMBDA(row_, ARRAYTOTEXT(UNIQUE(TRANSPOSE(row_))) ))
6									2, 1, 7, 5
7									8, 6, 5, 9
8
9
10									1, 1, 3, 3, 3, 4, 4	=BYROW(A1:G3, LAMBDA(row_, ARRAYTOTEXT(SORT(TRANSPOSE(row_))) ))
11									1, 1, 2, 2, 5, 7, 7
12									5, 5, 6, 6, 8, 8, 9
13
14
15									4, 4, 3, 3, 3, 1, 1	=BYROW(A1:G3, LAMBDA(row_, ARRAYTOTEXT(SORT(TRANSPOSE(row_),,-1)) ))
16									7, 7, 5, 2, 2, 1, 1
17									9, 8, 8, 6, 6, 5, 5
18
Sheet1

Cell Formulas
Range	Formula
I5:I7	I5	=BYROW(A1:G3, LAMBDA(row_, ARRAYTOTEXT(UNIQUE(TRANSPOSE(row_))) ))
J5,J15,J10	J5	=FORMULATEXT(I5)
I10:I12	I10	=BYROW(A1:G3, LAMBDA(row_, ARRAYTOTEXT(SORT(TRANSPOSE(row_))) ))
I15:I17	I15	=BYROW(A1:G3, LAMBDA(row_, ARRAYTOTEXT(SORT(TRANSPOSE(row_),,-1)) ))
Dynamic array formulas.

 

[Xlambda]

Super cool!! ✌ There are so many ways. BYROW still cannot "spill" rows. And I have used TEXTJOIN because of its "ignore empty argument". It's good for handling blanks/null strings. Examples will follow.