AREVERSE

[Xlambda]

AREVERSE array reverse, calls ATEXTJOIN. Other lambda in minisheet AKEEP
For a single cell there is a simple recursion lambda, but for an array I choose a non recursive one.
!! recursive !! T_REVERSE(w)=LAMBDA(w,LET(n,LEN(w),r,RIGHT(w,1),IF(n=0,w,r&T_REVERSE(LEFT(w,n-1)))))

=LAMBDA(a,
    LET(r,ROWS(a),c,MAX(LEN(a)),s,SEQUENCE(,c),m,MID(a,s,1),
       ATEXTJOIN(INDEX(m,SEQUENCE(r),ABS(s-c-1)),,,)
    )
)

LAMBDA 7.0.xlsx
	A	B	C	D	E	F	G	H	I	J	K
1	check palindrome sentences	=AKEEP(A2:A5,T_CHARS(,2,),)		=AREVERSE(B2#)		=B2#=D2#
2	Murder for a jar of red rum	Murderforajarofredrum		murderforajarofredruM		TRUE
3	Borrow or rob?	Borroworrob		borroworroB		TRUE
4	Eva, can I see bees in a cave?	EvacanIseebeesinacave		evacaniseebeesInacavE		TRUE
5	Yo, banana boy!	Yobananaboy		yobananaboY		TRUE
6
7		is palindrome		=AREVERSE(B8:B13)		=B8:B13=D8#		=PROPER(LOWER(T_REVERSE(B8)))
8		Gigi		igiG		FALSE		Igig
9		1234abcdefg		gfedcba4321		FALSE		Gfedcba4321
10		Madam		madaM		TRUE		Madam
11		Civic		civiC		TRUE		Civic
12		Level		leveL		TRUE		Level
13		Radar		radaR		TRUE		Radar
14
15	for a single cell recursive lambda
16	T_REVERSE(w)=LAMBDA(w,LET(n,LEN(w),r,RIGHT(w,1),IF(n=0,w,r&T_REVERSE(LEFT(w,n-1)))))
17
18	other lambdas used
19	AKEEP
20
AREVERSE post

Cell Formulas
Range	Formula
B1,F7,D7,H7,F1,D1	B1	=FORMULATEXT(B2)
B2:B5	B2	=AKEEP(A2:A5,T_CHARS(,2,),)
D2:D5	D2	=AREVERSE(B2#)
F2:F5	F2	=B2#=D2#
D8:D13	D8	=AREVERSE(B8:B13)
F8:F13	F8	=B8:B13=D8#
H8:H13	H8	=PROPER(LOWER(T_REVERSE(B8)))
Dynamic array formulas.

 

[Xlambda]

Just saw latest MrExcel YT: Excel Search In Reverse (Jenny) - feat. Tommy Tutone - 2444, (19-Nov-2021) and I thought it's time to update the function using new lambda helper function MAP.
AREVERSE(a,[tn]), brand new function same name, same functionality, can handle 2D arrays, blanks (null strings), has new argument [tn] .
Has a new argument [tn], text/number, which can be omitted.
a: any array, 1D or 2D
[tn]: 0, or omitted, results are kept as text ; 1 or <>0, converts results into numeric values, wherever is possible.

=LAMBDA(a,[tn],LET(m,MAP(a,LAMBDA(a,CONCAT(MID(a,SEQUENCE(LEN(a),,LEN(a),-1),1)))),
      IF(a="","",IF(tn,IFERROR(--m,m),m))
      )
)

LAMBDA 1.1.5.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L
1	AREVERSE(a,[tn])
2	a: array
3	[tn]: text/number argument : 0,or omitted,text ; <>0 (1), numeric
4
5	Concept is very simple, MID extraction backwards, last to first char, CONCAT the result,
6	and MAP does this for each element of "a"
7
8	a		=MID(A9,SEQUENCE(LEN(A9),,LEN(A9),-1),1)					or
9	abcd		d					=MID(A9,LEN(A9)-SEQUENCE(LEN(A9))+1,1)
10			c		=CONCAT(C9#)			d
11			b		dcba			c
12			a					b
13								a
14	tn,omitted
15		a		=AREVERSE(A16:B18)
16	abcd	efgh		dcba	hgfe
17	!"·$%	ABCD		%$·"!	DCBA
18		A/b/c/D			D/c/b/A
19
20	As we know, every text function delivers text, including MID function.
21	If will ever need this text to be converted into numeric values, wherever
22	is possible, we can use tn=1
23
24	Special cases,nr. with leading/trailing 0's, negative numbers,dates in dates format
25
26				tn,omitted , all text			tn,1 =
27		a		=AREVERSE(A28:B33)			=AREVERSE(A28:B33,1)
28	1234	1230		4321	0321		4321	321
29	01230	27.35		03210	53.72		3210	53.72
30	a-b-c-d	A_B_C_D		d-c-b-a	D_C_B_A		d-c-b-a	D_C_B_A
31	-123.25	-123.25		52.321-	52.321-		52.321-	52.321-
32	123-	)123(		-321	(321)		-321	-321
33	19-Nov-21	19-11-21		91544	91544		91544	91544		¡¡year of reverse date is
34										2150, not 2050 !!
35	last row nr. format						last row in date format			=YEAR(H36)
36	44519	44519					20-08-50	20-08-50		2150
37
38				Note!! Reversing 1230 when tn=1 will loose the leading 0
39				Trailing 0's in reverse order will be lost when tn=1
40				Negative numbers with leading "-" or between () , reversed,will not be numbers
41				Dates reversed , with tn=1, will be some numbers
42					=> crazy format to get negative numbers
43
AREVERSE np1

Cell Formulas
Range	Formula
C8,J35,G27,D27,D15,E10,H9	C8	=FORMULATEXT(C9)
C9:C12	C9	=MID(A9,SEQUENCE(LEN(A9),,LEN(A9),-1),1)
H10:H13	H10	=MID(A9,LEN(A9)-SEQUENCE(LEN(A9))+1,1)
E11	E11	=CONCAT(C9#)
D16:E18	D16	=AREVERSE(A16:B18)
D28:E33	D28	=AREVERSE(A28:B33)
G28:H33	G28	=AREVERSE(A28:B33,1)
J36	J36	=YEAR(H36)
Dynamic array formulas.

 

[Xlambda]

LAMBDA 1.1.5.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S
1	¡¡ This post is for fun ONLY !!								What dates are symetric btwn years 1980-2000
2	Funny idea: What date is your birthdate in reverse order?								sequence of all dates formula
3	We can start a trend, to celebrate both dates, every year, the regular one and the reversed one ?								=SEQUENCE("31-12-00"-"1-1-80"+1,,"1-1-80")
4									symetric dates 1980-2000, single cell
5	To find out what date is our birthdate or any date in reverse order with a simple formulas:								=LET(x,SEQUENCE("31-12-00"-"1-1-80"+1,,"1-1-80"),y,AREVERSE(x,1),z,FILTER(x,x=y),TEXT(z,"dd-mmm-yy"))
6	=DATE(2021,12,31)		=AREVERSE(A7,1)		=TEXT(C7,"dd-mmm-yyyy")				12-Mar-80
7	31-12-21		16544		17-Apr-1945				20-Jun-80
8									28-Sep-80
9									06-Jan-81
10	single cell								16-Apr-81
11	=TEXT(AREVERSE(DATE(2021,12,31),1),"dd-mmm-yyyy")								25-Jul-81
12	17-Apr-1945								02-Nov-81
13									10-Feb-82
14	How many times we used birthdates of our loved ones, if not ours, as safe codes, pin codes?								21-Feb-82
15	We use them because are easy to remember, and we don't have to write them down.								01-Jun-82
16	Also , these are the first combinations that will be checked by bad guys (coworkers ?)								09-Sep-82
17	With this "encoding" we are safe now ? unless…there is an unless…								18-Dec-82
18	…the birthdate is symmetric.								28-Mar-83
19									06-Jul-83
20	Also, if we want to "encode" some table date column, we can use this method.								14-Oct-83
21	Nobody will know when a certain event really took place.?								22-Jan-84
22	(don't forget to hide the formula)								01-May-84
23									09-Aug-84
24	Let's hope that bad guys don't use Excel !!								27-Nov-84
25									07-Mar-85
26									15-Jun-85
27									23-Sep-85
28									01-Jan-86
29									11-Apr-86
30									20-Jul-86
31									28-Oct-86
32									05-Feb-87
33									16-May-87
34									03-Sep-87
35									12-Dec-87
36									21-Mar-88
37									29-Jun-88
38									07-Oct-88
39									15-Jan-89
40									25-Apr-89
41									03-Aug-89
42									11-Nov-89
43									19-Feb-90
44									09-Jun-90
45									17-Sep-90
46									26-Dec-90
47									05-Apr-91
48									14-Jul-91
49									22-Oct-91
50									30-Jan-92
51									09-May-92
52									17-Aug-92
53									25-Nov-92
54									15-Mar-93
55									23-Jun-93
56									01-Oct-93
57									09-Jan-94
58									19-Apr-94
59									28-Jul-94
60									05-Nov-94
61									13-Feb-95
62									24-May-95
63									01-Sep-95
64									20-Dec-95
65									29-Mar-96
66									07-Jul-96
67									15-Oct-96
68									23-Jan-97
69									03-May-97
70									11-Aug-97
71									19-Nov-97
72									27-Feb-98
73									07-Jun-98
74									25-Sep-98
75									03-Jan-99
76									13-Apr-99
77									22-Jul-99
78									30-Oct-99
79									07-Feb-00
80									17-May-00
81									25-Aug-00
82									03-Dec-00
83
Fun with dates

Cell Formulas
Range	Formula
I5,A11,A6,C6,E6	I5	=FORMULATEXT(I6)
I6:I82	I6	=LET(x,SEQUENCE("31-12-00"-"1-1-80"+1,,"1-1-80"),y,AREVERSE(x,1),z,FILTER(x,x=y),TEXT(z,"dd-mmm-yy"))
A7	A7	=DATE(2021,12,31)
C7	C7	=AREVERSE(A7,1)
E7	E7	=TEXT(C7,"dd-mmm-yyyy")
A12	A12	=TEXT(AREVERSE(DATE(2021,12,31),1),"dd-mmm-yyyy")
Dynamic array formulas.

 

[Xlambda]

LAMBDA 1.1.5.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	Encoding/Deconding a date set, dealing with leading 0's scenario
2
3	sample, dates column		dates, nr. format		encoding dates nr. format		encoding, dates format		decoding the encoding		deconding dates, single cell
4	=SEQUENCE(21,,TODAY())		=SEQUENCE(21,,TODAY())		=AREVERSE(C5#,1)				=IF(LEN(E5#)=4,"0"&E5#,E5#)		=AREVERSE(IF(LEN(E5#)=4,"0"&E5#,E5#),1)
5	20-11-21		44520		2544		18-12-06		02544		44520		20-11-21
6	21-11-21		44521		12544		05-05-34		12544		44521		21-11-21
7	22-11-21		44522		22544		20-09-61		22544		44522		22-11-21
8	23-11-21		44523		32544		05-02-89		32544		44523		23-11-21
9	24-11-21		44524		42544		23-06-16		42544		44524		24-11-21
10	25-11-21		44525		52544		09-11-43		52544		44525		25-11-21
11	26-11-21		44526		62544		27-03-71		62544		44526		26-11-21
12	27-11-21		44527		72544		12-08-98		72544		44527		27-11-21
13	28-11-21		44528		82544		29-12-25		82544		44528		28-11-21
14	29-11-21		44529		92544		16-05-53		92544		44529		29-11-21
15	30-11-21		44530		3544		13-09-09		03544		44530		30-11-21
16	01-12-21		44531		13544		29-01-37		13544		44531		01-12-21
17	02-12-21		44532		23544		16-06-64		23544		44532		02-12-21
18	03-12-21		44533		33544		02-11-91		33544		44533		03-12-21
19	04-12-21		44534		43544		20-03-19		43544		44534		04-12-21
20	05-12-21		44535		53544		05-08-46		53544		44535		05-12-21
21	06-12-21		44536		63544		21-12-73		63544		44536		06-12-21
22	07-12-21		44537		73544		09-05-01		73544		44537		07-12-21
23	08-12-21		44538		83544		24-09-28		83544		44538		08-12-21
24	09-12-21		44539		93544		10-02-56		93544		44539		09-12-21
25	10-12-21		44540		4544		09-06-12		04544		44540		10-12-21
26
27													checks initial data
28
Encoding-Decoding

Cell Formulas
Range	Formula
A4,C4,E4,I4,K4	A4	=FORMULATEXT(A5)
A5:A25,C5:C25	A5	=SEQUENCE(21,,TODAY())
E5:E25	E5	=AREVERSE(C5#,1)
G5:G25,M5:M25	G5	=E5#
I5:I25	I5	=IF(LEN(E5#)=4,"0"&E5#,E5#)
K5:K25	K5	=AREVERSE(IF(LEN(E5#)=4,"0"&E5#,E5#),1)
Dynamic array formulas.

 

[GeertD]

That CONCAT MID SEQUENCE LEN LEN sounds vaguely familiar...

 

[Xlambda]

Haha?... I know why!! Because I have posted same formula 1h before you did.
If you go to comment section of the YT video, and choose "SORT BY", "Newest first" you will find my post, 1h before you. ?
I never used LEFT(RIGHT...construction in my functions, always MID, even in my very first iteration of this function, back on april 2021
See YT screen capture attached. ?✌

 

[GeertD]

Haha?... I know why!! Because I have posted same formula 1h before you did.
If you go to comment section of the YT video, and choose "SORT BY", "Newest first" you will find my post, 1h before you. ?
I never used LEFT(RIGHT...construction in my functions, always MID, even in my very first iteration of this function, back on april 2021
See YT screen capture attached. ?✌

Well, what do you know!... Great minds think alike (and the younger ones are quicker to respond )
Truthfully, I didn't see your comment before, but the LEFT-RIGHT trick triggered the same response.
As mentioned online: the only downsides are: needing the LEN function twice and a formula that looks slightly more complicated because of the arguments.
The plus sides are: we don't need to construct an "escalating" vector of strings of which we only need the first characters.
So for very large strings (and/or an entire column of those things) our formula is noticeably more efficient. For small problems, the performance difference is inconceivable.

 

[Xlambda]

I know you did not see it. Sometimes, YT, has this glitch. Hides comments from the main "wall" but reveals them if we click "Newest first". Not the first time when this happened. Sometimes they disappear entirely to other users even if for the one who posted it is there. To check how others are seeing our posts we have to sign out and check if is really there.
Anyhow, was fun when I saw you came with same idea. ?