Archive row if condition meets

[Jerfyjer169]

I did some research on how previous posts may help in doing what I want. Those may be a little too complicated for me to understand as I have only came across VBA recently.

I have a list of invoices that are ready for payment. For each invoice that is due for payment, I will mark it as "Y" in Column A otherwise blank. I will need to archive each row that is marked with a "Y" in Column A on the "Archive" spreadsheet.

What I want to do is, if Column A is not empty, then highlight that row, copy and paste value on the next empty row on the archive spreadsheet.

Would VBA be the best option for this? If VBA is the best option, how should I go about this?

 

[alansidman]

This vba solution should do it for you

Option Explicit


Sub Archive()
    Dim s1 As Worksheet, s2 As Worksheet
    Set s1 = Sheets("Sheet1")
    Set s2 = Sheets("Archive")
    Dim i As Long, lr As Long, lr2 As Long
    lr = s1.Range("B" & Rows.Count).End(xlUp).Row
    Application.ScreenUpdating = False
    For i = lr To 2 Step -1    'Assumes first row is a header
        If s1.Range("A" & i) = "Y" Then
            lr2 = s2.Range("A" & Rows.Count).End(xlUp).Row + 1
            s1.Range("A" & i).EntireRow.Copy s2.Range("A" & lr2)
            s1.Range("A" & i).EntireRow.Delete
        End If
    Next i
    Application.CutCopyMode = False
    Application.ScreenUpdating = True
    MsgBox "Action Complete"


End Sub

Standard Module
How to install your new code
Copy the Excel VBA code
Select the workbook in which you want to store the Excel VBA code
Press Alt+F11 to open the Visual Basic Editor
Choose Insert > Module
Edit > Paste the macro into the module that appeared
Close the VBEditor
Save your workbook (Excel 2007+ select a macro-enabled file format, like *.xlsm)


To run the Excel VBA code:
Press Alt-F8 to open the macro list
Select a macro in the list
Click the Run button

 

[Jerfyjer169]

Thanks for the solution Alan!

It did exactly what I wanted!