Appending Files in subfolders with inconsistent names

[Walser52]

So I have this folder structure.

The MainFolder (let’s call it level 0) has any number of folders (Folder1, Folder2…). The names are not in any sequence.

At level 1 (i.e. inside each folder) there is a ‘summary’ DTA file (xyz.DTA) in the case shown but the name of this file changes randomly across folders. At level1 there is also a subfolder (SUBFOLDER). This subfolder has the same name in all the other folders.

At level2 there is are two more DTA files (CHARGE.DTA and DISCHARGE.DTA). Again these names are consistent in the other folders too.

The DTA files are basically text files that are tab delimited.

I want to combine all the summary files (the ones at level1) in parallel. And I want to do the same with the CHARGE files and the DISCHARGE files.

I am looking into how to loop through subfolders but if anyone knows a similar problem that I can appropriate for my needs that could save time.

Thanks in Advance.

 

[Walser52]

To clarify: I want to combine all the summary files in parallel in one worksheet. All the CHARGE files (again in parallel) in a second worksheet. And all the DISCHARGE files (once again in parallel) in a third worksheet.

 

[Marc L]

​

As they are many samples whatever the Excel forum to scan subfolders …​

​

Or zip a root folder structure with some samples text files including in the root folder (MainFolder) the expected workbook result​

saved as .xlsb binary format according to the samples text files then link the zip file on a files host website like Dropbox …​

 

[Walser52]

​

As they are many samples whatever the Excel forum to scan subfolders …​

​

Or zip a root folder structure with some samples text files including in the root folder (MainFolder) the expected workbook result​

saved as .xlsb binary format according to the samples text files then link the zip file on a files host website like Dropbox …​

I've uploaded the samples and the 'Desired Output' here on Google Drive.

 

[Walser52]

I've figured it out (though the code is clunky and not suitable to post here)

I guess this is redundant now but I can't find the delete option

 

[Marc L]

According to your attachment a VBA demonstration for starters, the workbook must be saved in the main folder :​

Sub TextImport(P$, ByVal F$, S&)
     Dim C%
         F = Dir$(P & F):  If F = "" Then Exit Sub
         C = Worksheets(S).UsedRange.Columns.Count
    With Worksheets(S).QueryTables.Add("TEXT;" & P & F, Worksheets(S).Cells(C - (C > 1)))
        .AdjustColumnWidth = True
        .RefreshStyle = xlOverwriteCells
        .TextFileDecimalSeparator = "."
        .TextFileParseType = xlDelimited
        .TextFileTabDelimiter = True
        .TextFileTextQualifier = xlTextQualifierNone
        .Refresh False:  .Delete
    End With
End Sub

Sub Demo1()
    Dim Obj As Object, P$
        For Each Obj In Worksheets:  Obj.UsedRange.Clear:  Next
        Application.ScreenUpdating = False
    For Each Obj In CreateObject("Scripting.FileSystemObject").GetFolder(ThisWorkbook.Path).SubFolders
         P = Obj.Path & "\"
         TextImport P, "*.DTA", 1
         P = P & "CHARGE_DISCHARGE\"
         TextImport P, "CHARGE_#1.DTA", 2
         TextImport P, "DISCHARGE_#1.DTA", 3
    Next
        Application.ScreenUpdating = True
End Sub