APALINDROME

[Xlambda]

APALINDROME checks an array for palindromes. calls AKEEP , AREVERSE

=LAMBDA(a,
    LET(x,AKEEP(a,T_CHARS(,2,),),y,AREVERSE(x),
       IF(x=y,"Yes !","No !")
    )
)

LAMBDA 7.0.xlsx
	A	B	C	D	E
1	check palindrome sentences		=APALINDROME(A2:A6)
2	¡ Murder for a jar of red rum !		Yes !
3	Borrow or rob?		Yes !
4	Eva, can I see bees in a cave?		Yes !
5	Yo, banana boy!		Yes !
6	Radar is radar !		No !
7
APALINDROME post

Cell Formulas
Range	Formula
C1	C1	=FORMULATEXT(C2)
C2:C6	C2	=APALINDROME(A2:A6)
Dynamic array formulas.

 

[schardt679]

How do you do this? Everytime I think of something, I check here minutes later you post the exact LAMBDA. I was just thinking of a PALINDROME LAMBDA. Great work

 

[Xlambda]

Hi, thanks, does not matter, if you have a different approach you should post. Only time, and other users will tell which one will get traction.
On 98% of the cases when I write a formula, I am stuck to the first idea that comes to my mind, and this could make me blind to other better solutions, solutions that other eyes can see, and so on.
So, I encourage you to post, you are a very good exceler. ✌?

 

[lrobbo314]

I've been playing around with making recursive functions.

Came up with a way to do a PALINDROME function recursively.

PALINDROME

=LAMBDA(
    text,
        IF(
            AOR(LEN(text),"0,1"),
                TRUE,
                IF(
                    LEFT(text)=RIGHT(text),
                        PALINDROME(MID(text,2,LEN(text)-2)),
                        FALSE
                )
            )
)

PALINDROME
	J	K
21	racecar	TRUE
22	abba	TRUE
23	monkey	FALSE
Sheet5

Cell Formulas
Range	Formula
K21:K23	K21	=PALINDROME(J21)

Helper function AOR, checks to see if any value in comma separated string is equal to value.

AOR

=LAMBDA(
    val,oStr,
        LET(
            ts,TEXTSPLIT(oStr,","),
            OR(
                MAP(
                    ts,
                    LAMBDA(
                        x,
                        IFERROR(
                            x+0=val,
                            x=val
                        )
                    )
                )
            )
        )
)

 

[Xlambda]

Cool that you play with recursive functions !!
In this case, my function was designed to work not only with single words in single cells, but with an array vector of sentences with random punctuation marks.
Anyhow, if I would have designed it for single words only palindrome check, I would have used one of these 2:
ISPLNDRM(x) - non recursive

=LAMBDA(x,LET(l,LEN(x),s,SEQUENCE(l),AND(MID(x,s,1)=MID(x,l-s+1,1))))

PLNDRM(x) - recursive (does not call any helper function)

=LAMBDA(x,LET(l,LEN(x),IF(l<2,TRUE,IF(LEFT(x,1)=RIGHT(x,1),PLNDRM(MID(x,2,l-2)),FALSE))))

Book1.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L
1			Wrong results for sentences
2			lrobbo314's fction
3	¡ Murder for a jar of red rum !	FALSE	=PALINDROME(A3)
4	Borrow or rob?	FALSE	=PALINDROME(A4)
5	Eva, can I see bees in a cave?	FALSE	=PALINDROME(A5)
6	Yo, banana boy!	FALSE	=PALINDROME(A6)
7
8			Single cells, single words
9			non recursive			recursive
10
11	aba	TRUE	=ISPLNDRM(A11)		TRUE	=PLNDRM(A11)
12	abba	TRUE	=ISPLNDRM(A12)		TRUE	=PLNDRM(A12)
13	racecar	TRUE	=ISPLNDRM(A13)		TRUE	=PLNDRM(A13)
14	A12321A	TRUE	=ISPLNDRM(A14)		TRUE	=PLNDRM(A14)
15	xyzyx	TRUE	=ISPLNDRM(A15)		TRUE	=PLNDRM(A15)
16	Level	TRUE	=ISPLNDRM(A16)		TRUE	=PLNDRM(A16)
17	Civic	TRUE	=ISPLNDRM(A17)		TRUE	=PLNDRM(A17)
18	Kayak	TRUE	=ISPLNDRM(A18)		TRUE	=PLNDRM(A18)
19	nopalindrome	FALSE	=ISPLNDRM(A19)		FALSE	=PLNDRM(A19)
20
21		ISPLNDRM(x) =
22		=LAMBDA(x,LET(l,LEN(x),s,SEQUENCE(l),AND(MID(x,s,1)=MID(x,l-s+1,1))))
23
24					PLNDRM(x) =
25					=LAMBDA(x,LET(l,LEN(x),IF(l<2,TRUE,IF(LEFT(x,1)=RIGHT(x,1),PLNDRM(MID(x,2,l-2)),FALSE))))
26
Sheet1

Cell Formulas
Range	Formula
C3:C6	C3	=FORMULATEXT(B3:B6)
B3:B6	B3	=PALINDROME(A3)
C11:C19,F11:F19	C11	=FORMULATEXT(B11:B19)
B11:B19	B11	=ISPLNDRM(A11)
E11:E19	E11	=PLNDRM(A11)
Dynamic array formulas.

 

[lrobbo314]

Here is another way that I came up with.

Also, just for fun, I asked ChatGPT to write a palindrome function. It failed 3 times before reverting to VBA. The VBA was a 1-liner and it worked. But, I think we're safe from GPT for a while.

XPALINDROME

=LAMBDA(range,
    MAP(range,
        LAMBDA(t,
            LET(n,INT(LEN(t)/2),
            r,REVTEXT(t),
                LEFT(t,n)=LEFT(r,n))
        )
    )
)

REVTEXT

=LAMBDA(text,
    LET(n,LEN(text),
        TEXTJOIN("",,MID(text,SEQUENCE(n,,n,-1),1))
    )
)

 

[Xlambda]

Just for fun "comment" : if XPALINDROME already calls r,REVTEXT(t), I don't think that comparing only half of the string, LEFT(t,n)=LEFT(r,n), will make the formula more efficient than using only t=r

=LAMBDA(range,
    MAP(range,
        LAMBDA(t,
            LET(r,REVTEXT(t),
                t=r)
        )
    )
)

 

[lrobbo314]

I realized that after I posted it, lol. Was kinda hoping you wouldn't notice.

 

[Xlambda]

I realized that after I posted it, lol. Was kinda hoping you wouldn't notice.

. Lol.
Anyhow, an updated 2023 APLNDRM(ar) function, Array Palindrome: checks an array of sentences for palindromes. Does not call any other function.

=LAMBDA(ar,
    LET(
        a, CONCAT(REDUCE(UPPER(ar), CHAR(SEQUENCE(26, , 65)), LAMBDA(v, i, SUBSTITUTE(v, i, "")))),
        r, REDUCE(ar, UNIQUE(MID(a, SEQUENCE(LEN(a)), 1)), LAMBDA(v, i, SUBSTITUTE(v, i, ""))),
        p, LAMBDA(x, LET(l, LEN(x), s, SEQUENCE(l), AND(MID(x, s, 1) = MID(x, l - s + 1, 1)))),
        MAP(r, p)
    )
)

Cool palindrome sentences from: 190+ Fun, Interesting Palindrome Words
Let's check them all.

Book1.xlsx
	A	B	C	D	E	F	G	H
1
2			=TEXTSPLIT(A3,,CHAR(10))		=APLNDRM(C3#)
3	Dammit, I’m mad! A man, a plan, a canal – Panama. Don’t nod. No lemon, no melon! Bird rib. Go hang a salami, I’m a lasagna hog. Do geese see God? Mr. Owl ate my metal worm. Was it a car or a cat I saw? Borrow or rob? I did, did I? Evil did I dwell; lewd I did live. Rats live on no evil star. My gym. No devil lived on. Ma is a nun, as I am. A nut for a jar of tuna. Yo, banana boy! Red rum, sir, is murder. Madam, in Eden, I’m Adam. Taco cat. Al lets Della call Ed “Stella.” Amore, Roma. As I pee sir, I see Pisa! Dennis sinned. Step on no pets. UFO tofu? But sad Eva saved a stub. No trace; not one carton. No, sir, prefer prison. Do nine men interpret? “Nine men,” I nod. Bombard a drab mob. No “x” in “Nixon”. Ma is as selfless as I am. Gateman sees name, garageman sees name tag. A Toyota. Race fast, safe car. A Toyota. Top spot. Drab as a fool, aloof as a bard. Now I see bees, I won. Was it a cat I saw? Cigar? Toss it in a can. It is so tragic. Never odd or even Evade me, Dave. Race fast, safe car. Flee to me, remote elf. Naomi, did I moan? Ed, I saw Harpo Marx ram Oprah W. aside. Campus Motto: Bottoms up, Mac! Name now one man. Doc, note I dissent: a fast never prevents a fatness. I diet on cod. Rise to vote, sir. Senile felines. Murder for a jar of red rum. Dogma? I am God. Won’t lovers revolt now? Saw tide rose? So red it was. Stack cats. Did I draw Della too tall, Edward? I did? A Santa dog lived as a devil god at NASA. Meet animals; laminate ’em. Oozy rat in a sanitary zoo. So many dynamos! A tin mug for a jar of gum, Nita. Madam I’m Adam. Able was I, ere I saw Elba. Eva, can I see bees in a cave? Lived on Decaf; faced no Devil. Stella won no wallets. Cain: a maniac. Lonely Tylenol. No lemon, no melon.		Dammit, I’m mad!		TRUE		all palindromes?
4			A man, a plan, a canal – Panama.		TRUE		=AND(E3#)
5			Don’t nod.		TRUE		TRUE
6			No lemon, no melon!		TRUE
7			Bird rib.		TRUE
8			Go hang a salami, I’m a lasagna hog.		TRUE
9			Do geese see God?		TRUE
10			Mr. Owl ate my metal worm.		TRUE
11			Was it a car or a cat I saw?		TRUE
12			Borrow or rob?		TRUE
13			I did, did I?		TRUE
14			Evil did I dwell; lewd I did live.		TRUE
15			Rats live on no evil star.		TRUE
16			My gym.		TRUE
17			No devil lived on.		TRUE
18			Ma is a nun, as I am.		TRUE
19			A nut for a jar of tuna.		TRUE
20			Yo, banana boy!		TRUE
21			Red rum, sir, is murder.		TRUE
22			Madam, in Eden, I’m Adam.		TRUE
23			Taco cat.		TRUE
24			Al lets Della call Ed “Stella.”		TRUE
25			Amore, Roma.		TRUE
26			As I pee sir, I see Pisa!		TRUE
27			Dennis sinned.		TRUE
28			Step on no pets.		TRUE
29			UFO tofu?		TRUE
30			But sad Eva saved a stub.		TRUE
31			No trace; not one carton.		TRUE
32			No, sir, prefer prison.		TRUE
33			Do nine men interpret? “Nine men,” I nod.		TRUE
34			Bombard a drab mob.		TRUE
35			No “x” in “Nixon”.		TRUE
36			Ma is as selfless as I am.		TRUE
37			Gateman sees name, garageman sees name tag.		TRUE
38			A Toyota. Race fast, safe car. A Toyota.		TRUE
39			Top spot.		TRUE
40			Drab as a fool, aloof as a bard.		TRUE
41			Now I see bees, I won.		TRUE
42			Was it a cat I saw?		TRUE
43			Cigar? Toss it in a can. It is so tragic.		TRUE
44			Never odd or even		TRUE
45			Evade me, Dave.		TRUE
46			Race fast, safe car.		TRUE
47			Flee to me, remote elf.		TRUE
48			Naomi, did I moan?		TRUE
49			Ed, I saw Harpo Marx ram Oprah W. aside.		TRUE
50			Campus Motto: Bottoms up, Mac!		TRUE
51			Name now one man.		TRUE
52			Doc, note I dissent: a fast never prevents a fatness. I diet on cod.		TRUE
53			Rise to vote, sir.		TRUE
54			Senile felines.		TRUE
55			Murder for a jar of red rum.		TRUE
56			Dogma? I am God.		TRUE
57			Won’t lovers revolt now?		TRUE
58			Saw tide rose? So red it was.		TRUE
59			Stack cats.		TRUE
60			Did I draw Della too tall, Edward? I did?		TRUE
61			A Santa dog lived as a devil god at NASA.		TRUE
62			Meet animals; laminate ’em.		TRUE
63			Oozy rat in a sanitary zoo.		TRUE
64			So many dynamos!		TRUE
65			A tin mug for a jar of gum, Nita.		TRUE
66			Madam I’m Adam.		TRUE
67		Able was I, ere I saw Elba.		TRUE
68		Eva, can I see bees in a cave?		TRUE
69		Lived on Decaf; faced no Devil.		TRUE
70		Stella won no wallets.		TRUE
71		Cain: a maniac.		TRUE
72		Lonely Tylenol.		TRUE
73		No lemon, no melon.		TRUE
74
Sheet2

Cell Formulas
Range	Formula
E2,G4,C2	E2	=FORMULATEXT(E3)
C3:C73	C3	=TEXTSPLIT(A3,,CHAR(10))
E3:E73	E3	=APLNDRM(C3#)
G5	G5	=AND(E3#)
Dynamic array formulas.

 

[Xlambda]

Book1.xlsx
	A
1	The Longest Palindrome Examples
2
3	Are we not pure? “No sir!” Panama’s moody Noriega brags. “It is garbage!” Irony dooms a man; a prisoner up to new era.
4	T. Eliot, top bard, notes putrid tang emanating, is sad. I’d assign it a name: gnat dirt upset on drab pot-toilet.
5	Embargos are macabre. Sad Nell, listen O, not to no nets. I’ll lend a Serb a camera, so grab me.
6	Er, go on, trap Steven in, I say. Me oh my. Nor can an “air” bee sew. We see, Brian. An acronym? Hoe my asinine vet’s part? No, ogre.
7	Are we not pure? “No sir!” Panama’s moody Noriega brags. “It is garbage!” Irony dooms a man; a prisoner up to new era.
8	“Son, say a papaya.” “Papayas.” “No ‘s.'”
9	Dennis, Nell, Edna, Leon, Nedra, Anita, Rolf, Nora, Alice, Carol, Leo, Jane, Reed, Dena, Dale, Basil, Rae, Penny, Lana, Dave, Denny, Lena, Ida, Bernadette, Ben, Ray, Lila, Nina, Jo, Ira, Mara, Sara, Mario, Jan, Ina, Lily, Arne, Bette, Dan, Reba, Diane, Lynn, Ed, Eva, Dana, Lynne, Pearl, Isabel, Ada, Ned, Dee, Rena, Joel, Lora, Cecil, Aaron, Flora, Tina, Arden, Noel, and Ellen sinned.
10
11	=APLNDRM(A3:A9)
12	TRUE
13	TRUE
14	TRUE
15	TRUE
16	TRUE
17	TRUE
18	TRUE
19
Sheet3

Cell Formulas
Range	Formula
A11	A11	=FORMULATEXT(A12)
A12:A18	A12	=APLNDRM(A3:A9)
Dynamic array formulas.