AONEDIM

[schardt679]

Checks if an array is one dimensional and returns "H", "V", or an error message.
Horizontal arrays (across columns) return "H", vertical arrays (down rows) return "V", and 2D arrays return a "One row/column" message.
Calls CELLCOUNT

=LAMBDA(Array,
      LET(Arr, Array,    RowCt, CELLCOUNT(Arr, 1),    ColCt, CELLCOUNT(Arr, 2),    Horiz?, ColCt>RowCt,
          ArrScan, AND(RowCt>1, ColCt>1),    ArrMSG, "One row/column",
          Result, IF(Horiz?, "H", "V"),    Return, IF(ArrScan, ArrMSG,  Result),
      Return)
  )

REVERSE Test.xlsx
	A	B	C	D	E	F
1		AONEDIM
2		Checks if an array is one dimensional (horizontal or vertical)
3		2D arrays return error message
4		1D arrays return "H" for horizontal {1,2,3} & "V" for vertical {1;2;3}
5		Used in many other functions to ensure correct syntax
6
7		Original Data			Result
8		Hello	There!		One row/column
9		My Name Patrick	I am 27.
10
11		Data array is 2D --> error message is returned
12		=AONEDIM(B8:C9)
13
14
15
16		Original Data			Result
17		Hello			V
18		There!
19		My Name Patrick
20		I am 27.
21
22		Data array is 1D --> "V" is returned
23		=AONEDIM(B17:B20)
24
25
26
27		Original Data
28		Hello	There!	My Name Patrick	I am 27.
29
30		Result
31		H
32
33		Data array is 1D --> "H" is returned
34		=AONEDIM(B28:E28)
35
AONEDIM

Cell Formulas
Range	Formula
E8	E8	=AONEDIM(B8:C9)
B12	B12	=FORMULATEXT(E8)
E17	E17	=AONEDIM(B17:B20)
B23	B23	=FORMULATEXT(E17)
B31	B31	=AONEDIM(B28:E28)
B34	B34	=FORMULATEXT(B31)

 

[schardt679]

AONEDIM has been updated. There is a new optional argument to treat single cells as horizontal arrays instead of vertical arrays. This will mainly be used in error checking LAMBDA arguments that only allow one dimensional arrays (or single cells). Before single cells always returned "V" for vertical. This was a problem for arguments requiring horizontal arrays (or single cells). For most applications, this argument will be omitted.

I found it was easier, shorter, and faster to add a little bit of code to this function than to add additional code in other functions.


AONEDIM checks if an array is one dimensional and returns "H", "V", or an error message.

Horizontal arrays (across columns) return "H", vertical arrays (down rows) return "V", and 2D arrays return a "One row/column" message.
Single cell behavior can be changed when checking if arrays are one dimensional using the optional Horizontal argument.
Calls CELLCOUNT.
Other functions on minisheet: AFORMULATEXT.

Screen Tip/ Comment: =AONEDIM(Array☛ range to check if it is one dimensional or not, [Horizontal]☛ 1=treat single cells as horizontal; 0/=treat as vertical) ⁂[]= optional; =default; =omit

The syntax is slightly different: ARESIZE(Array,[Horizontal])

There is one additional argument: [Horizontal].
1. Inputting 0 or omitting it, makes the function act normally: a single cell returns "V" for vertical array.
2. Inputting 1 for it makes a single cell return "H" for horizontal array.
Array: Required. Range to check if it is one dimensional or not.
[Horizontal]: Optional. 1☛ treat single cells as horizontal; 0 or ignored☛ treat as vertical.

=LAMBDA(Array,[Horizontal],
      LET(Arr, Array,          Hor, Horizontal,
             RowCt, CELLCOUNT(Arr, 1),          ColCt, CELLCOUNT(Arr, 2),
             ArrScan, AND(RowCt>1, ColCt>1),          ArrMSG, "One row/column",
             HorScan, AND(Hor<>{1,0}),          HorMSG, "Horizontal=1,0",
             ERRORS, IFS(ArrScan, ArrMSG,  HorScan, HorMSG,  1, 0),
             Single?, AND(RowCt=1, ColCt=1),          H?, ColCt>RowCt,
             Result, IF(OR(AND(Single?, Hor=1), H?), "H",  "V"),
             Return, IF(ERRORS<>0, ERRORS,  Result),
             Return
      )
  )

LAMBDA Examples.xlsx
	A	B	C	D	E	F
34		Original Data			Result
35		Hello There			V
36
37		Data is a single cell --> "H" is returned
38		Formula in cell E35☛ =AONEDIM(B35)
39
40
41
42		Original Data			Result
43		Hello There			H
44
45		Data is a single cell --> "H" is returned
46		Formula in cell E43☛ =AONEDIM(B43, 1)
47
AONEDIM

Cell Formulas
Range	Formula
E35	E35	=AONEDIM(B35)
B38,B46	B38	=AFORMULATEXT(E35)
E43	E43	=AONEDIM(B43, 1)

 

[schardt679]

Quick update: I just realized the updated syntax is wrong.

It shows ARESIZE(Array,[Horizontal]). It should be AONEDIM(Array,[Horizontal]).

If a page admin can change this, that would be great. I can report it for incorrect syntax if need be.