Always select the first row of a Filtered Block

[bribin]

Greetings
3 events can be triggered (events = 11, 12, 13) all in column “A”
Starting at range(“a51”) (the title row)
Filtering a block of 4 columns 49 rows, I want to capture to (“C48”) the value in column 3 of the 1st row displayed by the filter, for each event
The Macro I recorded works well on the first run,
Range("C48").Select
ActiveCell.FormulaR1C1 = "=R[10]C"
On subsequent runs it always selects "=R[10]C" (naturally!) when in fact "=R[23]C" or "=R[19]C" is the target
I would be grateful if someone; more knowledge than me, would help me overcome this dilemma.
Regards
John

 

[NoSparks]

Here's a couple of functions I tucked away some time back, unfortunately I didn't keep a link to the thread.

'First and Last rows of filtered data
'Rick Rothstein posted at MrExcel

Function GetFilteredRangeTopRow() As Long
  Dim HeaderRow As Long, LastFilterRow As Long
  On Error GoTo NoFilterOnSheet
  With ActiveSheet
    HeaderRow = .AutoFilter.Range(1).Row
    LastFilterRow = .Range(Split(.AutoFilter.Range.Address, ":")(1)).Row
    GetFilteredRangeTopRow = .Range(.Rows(HeaderRow + 1), .Rows(Rows.Count)). _
                                    SpecialCells(xlCellTypeVisible)(1).Row
    If GetFilteredRangeTopRow = LastFilterRow + 1 Then GetFilteredRangeTopRow = 0
  End With
NoFilterOnSheet:
End Function

Function GetFilteredRangeBottomRow() As Long
  Dim HeaderRow As Long, LastFilterRow As Long, Addresses() As String
  On Error GoTo NoFilterOnSheet
  With ActiveSheet
    HeaderRow = .AutoFilter.Range(1).Row
    LastFilterRow = .Range(Split(.AutoFilter.Range.Address, ":")(1)).Row
    Addresses = Split(.Range((HeaderRow + 1) & ":" & LastFilterRow). _
                      SpecialCells(xlCellTypeVisible).Address, "$")
    GetFilteredRangeBottomRow = Addresses(UBound(Addresses))
  End With
NoFilterOnSheet:
End Function

 

[bribin]

Thank you NoSparks both, for your timely solution and your foresight in harvesting those functions which instantly solved my problem.
Regards,
John