AFORMULATEXT

[schardt679]

AFORMULATEXT improves FORMULATEXT and returns a cell's formula as well as the cell's address or a message for non-formula cells.
Reference can be a single cell or an array of cells, despite what FORMULATEXT says (it says only upper-left most cell is used)

=LAMBDA(Reference,
      LET(Ref, Reference,    
          RefRow, ROW(Ref),    
          RefCol, COLUMN(Ref),    
          RefAdd, ADDRESS(RefRow, RefCol, 4),
          NoFormMSG, "No formula",    
          Result, "Formula in cell "&RefAdd&"☛ "&FORMULATEXT(Ref),
          Return, IFNA(Result, NoFormMSG),
          Return
      )
  )

LAMBDA Examples.xlsx
	A	B	C	D	E	F	G	H
1		AFORMULATEXT
2
3		Test	Possible Points	Your Score		Average
4		Test 1	100	100		91.67
5		Test 2	100	80
6		Midterm	100	80
7		Test 3	100	100
8		Test 4	100	90
9		Final	100	100
10
11		Formula in cell F4☛ =AVERAGE(D4#)
12
13
14
15		Test	Possible Points	Your Score	Percentage	Funtion	Value
16		Test 1	50	44	88.00%	Min:	75.00%
17		Test 2	50	41	82.00%	Max:	98.00%
18		Midterm	100	75	75.00%	Mean:	86.67%
19		Test 3	50	49	98.00%	Overall Grade:	85.75%
20		Test 4	50	43	86.00%
21		Final	100	91	91.00%
22		Total:	400	343
23
24		Formula in cell G16☛ =MIN(E16#)
25		Formula in cell G17☛ =MAX(E16#)
26		Formula in cell G18☛ =AVERAGE(E16#)
27		Formula in cell G19☛ =SUM(D22)/SUM(C22)
28
29
30
31		Value 1	Value 2
32		1	A
33		2	#VALUE!
34		4
35
36		No formula	No formula
37		Formula in cell B33☛ =B32+1	Formula in cell C33☛ =C32+1
38		Formula in cell B34☛ =B33*2	No formula
39
AFORMULATEXT

Cell Formulas
Range	Formula
C4:C9	C4	=SEQUENCE(ROWS(B4:B9),, 100, 0)
D4:D9	D4	=RANDARRAY(ROWS(B4:B9),, 75, 100, 1)
F4	F4	=AVERAGE(D4#)
B11	B11	=AFORMULATEXT(F4)
E16:E21	E16	=D16:D21/C16:C21
G16	G16	=MIN(E16#)
G17	G17	=MAX(E16#)
G18	G18	=AVERAGE(E16#)
G19	G19	=SUM(D22)/SUM(C22)
D16:D21	D16	=RANDBETWEEN(0.75*C16, C16)
C22:D22	C22	=SUM(C16:C21)
B24:B27	B24	=AFORMULATEXT(G16:G19)
B33:C33	C33	=C32+1
B34	B34	=B33*2
B36:C38	B36	=AFORMULATEXT(B32:C34)
Dynamic array formulas.