Advice for my code that hides shapes on worksheet

[ipbr21054]

This code shown below will hides shapes etc on the worksheet.

Sub HideButtons()
On Error GoTo ErrHand:
Call TurnOffFeatures ' Stop events etc...

' Define the original sheet
Dim wks As Worksheet
Set wks = Worksheets("INV")

' Define the copied sheet
If wks.Range("G13").Value <> "" Then                    ' if name
    wks.Copy After:=Worksheets(Sheets.count)    ' Copy to last sheets
    Worksheets(Sheets.count).NAME = wks.Range("G13").Value           ' rename sheet
    Dim wksNew As Worksheet
    Set wksNew = Worksheets(wks.Range("G13").Value)     ' set wksNew as new sheet (Selected by name: I would recommend using this)
End If

' Hide all others CommanButtons except "PrintGeneratedSheet"
Dim Shape As Shape
For Each Shape In wksNew.Shapes
    If Shape.NAME <> "PrintGeneratedSheet" Then
        Shape.Visible = False
    End If
Next

ErrHand:
    Call TurnOnFeatures ' Enable events etc...
End Sub

Ive since added CheckBox1 & CheckBox2 & would like them to be shown on the page.

See screenshot of current page where they should be shown.
Please advise how i alter the code to see the 2 Checkboxes.

I did add this but made no difference & was still hidden

    If Shape.NAME <> "CheckBox1" Then
        Shape.Visible = True
    End If

 

[dmt32]

Hi
untested but see if this update to your code will do what you want

Sub HideButtons()
    Dim StayVisible     As Variant
    Dim Shape           As Shape
    Dim NewSheetName    As String
    Dim wks             As Worksheet, wksNew      As Worksheet
    
    'list all shape names that stay visible
    StayVisible = Array("PrintGeneratedSheet", "CheckBox1", "CheckBox2")
    
    On Error GoTo ErrHand:
    ' Stop events etc...
    
    ' Define the original sheet
    With ThisWorkbook
        Set wks = .Worksheets("INV")
        
        NewSheetName = wks.Range("G13").Value
        
        'check if name exists
        If Not Evaluate("ISREF('" & NewSheetName & "'!A1)") Then
        
            Call TurnOffFeatures
            
            ' Copy to last sheets
            wks.Copy After:=.Worksheets(Sheets.Count)
            ' rename sheet
            .Worksheets(Sheets.Count).Name = NewSheetName
            
            ' set wksNew as new sheet
            Set wksNew = .Worksheets(NewSheetName)
            
            ' Hide all sahpes not in StayVisible array
            
            For Each Shape In wksNew.Shapes
                Shape.Visible = Not IsError(Application.Match(Shape.Name, StayVisible, 0))
            Next
            
        End If
    End With
    
ErrHand:
    ' Enable events etc...
    Call TurnOnFeatures
End Sub

Dave

 

[ipbr21054]

Perfect many thanks.

 

[dmt32]

Perfect many thanks.

welcome & appreciate your feedback

Dave