Adding to my soccer team's stat sheet. Need help with top 3 ranking.

[ExcelNoob2022]

Hello Excel Wizards, I come to you humbly as a man who knows not what he does. I came here for help with this spreadsheet before and some nice souls helped me get it up and running. Recently, I wanted to add to it and tried copying the work of others and have failed misreably. Please advise.

Essentially I am just trying to create a top three list of the names and stats of the players in the correct categories. For some reason I can't seem to isolate the column I want without getting all of them involved.

Team Stats.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
25	Player	GP	GPG	APG	SPG	Shot%	GAPG	Save%				Shot Percentage
26	Adelyn Holexa	12	0.08	0	0.42	20%	0.92	78%				1st	#VALUE!	###
27	Alice Felton	10	0.20	0.3	0.80	25%	0.00					2nd	#VALUE!	###
28	Blakely Haines	8	-	0	0.25	0%	0.00					3rd	#VALUE!	###
29	Brooke Risser	12	1.67	0.42	4.58	36%	0.08	86%				Goals Per Game
30	Charlie Zetterberg	7	-	0	0.29	0%	0.00	100%				1st	#SPILL!	12	1.66667
31	Dempsey Meyers	14	0.64	0.14	2.07	31%	0.00					2nd		14	1.57143
32	Eire Biggs	5	0.20	0	1.60	13%	0.00					3rd		14	1.57143
33	Emery Schmitz	16	0.44	0.13	0.81	54%	0.44	81%				Assists Per Game
34	Grace Hart	4	-	0	0.00		0.00					1st	#SPILL!	14	0.5
35	Hayden Haines	8	0.13	0.13	3.50	4%	0.13	80%				2nd		12	0.41667
36	Holly Beckman	12	0.25	0.08	1.00	25%	0.00					3rd		10	0.3
37	Hope Hoffman	9	0.22	0	1.11	20%	0.00					Save Percentage
38	Jenna Thurlkill	11	0.18	0	0.55	33%	0.00					1st	#SPILL!	12	0
39	Lauren Martinsen	14	1.57	0.5	3.93	40%	0.00					2nd		10	0
40	Lyla Dupont	10	0.20	0.2	1.80	11%	0.00					3rd		8	0
41	Nia Reilly	14	1.57	0.29	4.29	37%	0.14	78%				Games Played
42	Zuzu Gilman	12	0.25	0.17	0.42	60%	0.00					1st	Emery Schmitz	16
43	TEAM AVERAGE	10.47	0.45	0.14	1.61	26%	0.10	84%				2nd	Dempsey Meyers	14
44												3rd	Lauren Martinsen	14
Main

Cell Formulas
Range	Formula
C26:C42	C26	=B3/B26
D26:D42	D26	=C3/B26
E26:E42	E26	=D3/B26
F26:F33,F35:F42	F26	=B3/D3
H26,H41,H35,H33,H29:H30	H26	=H3/(G3+H3)
M26:N28	M26	=INDEX(SORT(A26:A42,F26:F42,2,-1),SEQUENCE(3),{1,2})
M30,N30:O32	M30	=INDEX(SORT(A26:C42,2,-1),SEQUENCE(3),{1,2})
G26:G42	G26	=G3/B26
M34,N34:O36	M34	=INDEX(SORT(A26:D42,3,-1),SEQUENCE(3),{1,3})
M38,N38:O40	M38	=INDEX(SORT(A26:H43,8,-1),SEQUENCE(3),{1,8})
M42:N44	M42	=INDEX(SORT(A26:B42,2,-1),SEQUENCE(3),{1,2})
B43:H43	B43	=AVERAGE(B26:B42)
Dynamic array formulas.

 

[KRice]

Give this a try...your post had formulas that reference cells that weren't included, so those showed up with errors. Consequently, I used hard-wired values in the dark blue-shaded region. I noted that for GPG, the "-" that appear will preferentially sort to the top of the list (which is not what you want). If you can avoid the "-" and simply leave those cells blank, that would be better. I've overwritten the hyphens with blanks in that column.

MrExcel_20220430.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
25	Player	GP	GPG	APG	SPG	Shot%	GAPG	Save%				Shot Percentage
26	Adelyn Holexa	12	0.08	0	0.42	0.2	0.92	0.78				1st	Zuzu Gilman	0.6
27	Alice Felton	10	0.2	0.3	0.8	0.25	0					2nd	Emery Schmitz	0.54
28	Blakely Haines	8		0	0.25	0	0					3rd	Lauren Martinsen	0.4
29	Brooke Risser	12	1.67	0.42	4.58	0.36	0.08	0.86				Goals Per Game
30	Charlie Zetterberg	7		0	0.29	0	0	1				1st	Brooke Risser	1.67	the "-" create problem
31	Dempsey Meyers	14	0.64	0.14	2.07	0.31	0					2nd	Lauren Martinsen	1.57
32	Eire Biggs	5	0.2	0	1.6	0.13	0					3rd	Nia Reilly	1.57
33	Emery Schmitz	16	0.44	0.13	0.81	0.54	0.44	0.81				Assists Per Game
34	Grace Hart	4		0	0		0					1st	Lauren Martinsen	0.5
35	Hayden Haines	8	0.13	0.13	3.5	0.04	0.13	0.8				2nd	Brooke Risser	0.42
36	Holly Beckman	12	0.25	0.08	1	0.25	0					3rd	Alice Felton	0.3
37	Hope Hoffman	9	0.22	0	1.11	0.2	0					Save Percentage
38	Jenna Thurlkill	11	0.18	0	0.55	0.33	0					1st	Charlie Zetterberg	1
39	Lauren Martinsen	14	1.57	0.5	3.93	0.4	0					2nd	Brooke Risser	0.86
40	Lyla Dupont	10	0.2	0.2	1.8	0.11	0					3rd	Emery Schmitz	0.81
41	Nia Reilly	14	1.57	0.29	4.29	0.37	0.14	0.78				Games Played
42	Zuzu Gilman	12	0.25	0.17	0.42	0.6	0					1st	Emery Schmitz	16
43	TEAM AVERAGE	10.47	0.45	0.14	1.61	0.26	0.1	0.84				2nd	Dempsey Meyers	14
44												3rd	Lauren Martinsen	14
Sheet6

Cell Formulas
Range	Formula
M26:N28	M26	=INDEX(SORT($A$26:$H$42,6,-1),SEQUENCE(3),{1,6})
M30:N32	M30	=INDEX(SORT($A$26:$H$42,3,-1),SEQUENCE(3),{1,3})
M34:N36	M34	=INDEX(SORT($A$26:$H$42,4,-1),SEQUENCE(3),{1,4})
M38:N40	M38	=INDEX(SORT($A$26:$H$42,8,-1),SEQUENCE(3),{1,8})
M42:N44	M42	=INDEX(SORT($A$26:$H$42,2,-1),SEQUENCE(3),{1,2})
Dynamic array formulas.

 

[ExcelNoob2022]

This is fantastic! Thank you so much for your help. I think it is 99.9% of the way there. After making the changes I only have one strange thing occurring. It's under the Save Percentage section, specifically the number one.

Team Stats.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	TOTAL TEAM STATS											WIN	LOSS	TIE
2	Player	Goals	Assists	Shots	Offsides	Fouls	Goals Allowed	Saves	Shut Out Halves	Hat Tricks		10	0	0
3	Adelyn Holexa	1	0	5	0	0	11	39	4	0		5	1	0
4	Alice Felton	2	3	8	0	0	0	0	0	0		0	0	0
5	Blakely Haines	0	0	2	0	0	0	0	1	0
6	Brooke Risser	20	5	55	0	0	1	6	1	2		Team Leaders
7	Charlie Zetterberg	0	0	2	1	0	0	3	2	0		Points
8	Dempsey Meyers	9	2	29	1	0	0	0	0	1		1st	Lauren Martinsen	51
9	Eire Biggs	1	0	8	1	0	0	0	0	0		2nd	Nia Reilly	48
10	Emery Schmitz	7	2	13	1	0	7	30	7	0		3rd	Brooke Risser	45
11	Grace Hart	0	0	0	0	0	0	0	0	0		Goals
12	Hayden Haines	1	1	28	0	1	1	4	2	0		1st	Lauren Martinsen	22
13	Holly Beckman	3	1	12	0	0	0	0	0	0		2nd	Nia Reilly	22
14	Hope Hoffman	2	0	10	1	0	0	0	0	0		3rd	Brooke Risser	20
15	Jenna Thurlkill	2	0	6	0	0	0	0	0	0		Assists
16	Lauren Martinsen	22	7	55	0	0	0	0	0	4		1st	Lauren Martinsen	7
17	Lyla Dupont	2	2	18	2	2	0	0	0	0		2nd	Brooke Risser	5
18	Nia Reilly	22	4	60	1	0	2	7	1	2		3rd	Nia Reilly	4
19	Zuzu Gilman	3	2	5	0	0	0	0	0	0		Saves
20	TOTAL	97	29	316	8	3	22	89	18	9		1st	Adelyn Holexa	39
21												2nd	Emery Schmitz	30
22												3rd	Nia Reilly	7
23
24	ADVANCED TEAM STATS											Team Leaders
25	Player	GP	GPG	APG	SPG	Shot%	GAPG	Save%				Shot Percentage
26	Adelyn Holexa	12	0.08	0	0.42	20%	0.92	78%				1st	Zuzu Gilman	60%
27	Alice Felton	10	0.20	0.3	0.80	25%	0.00					2nd	Emery Schmitz	54%
28	Blakely Haines	8		0	0.25	0%	0.00					3rd	Lauren Martinsen	40%
29	Brooke Risser	12	1.67	0.42	4.58	36%	0.08	86%				Goals Per Game
30	Charlie Zetterberg	7		0	0.29	0%	0.00	100%				1st	Brooke Risser	1.7
31	Dempsey Meyers	14	0.64	0.14	2.07	31%	0.00					2nd	Lauren Martinsen	1.6
32	Eire Biggs	5	0.20	0	1.60	13%	0.00					3rd	Nia Reilly	1.6
33	Emery Schmitz	16	0.44	0.13	0.81	54%	0.44	81%				Assists Per Game
34	Grace Hart	4		0	0.00		0.00					1st	Lauren Martinsen	0.5
35	Hayden Haines	8	0.13	0.13	3.50	4%	0.13	80%				2nd	Brooke Risser	0.4
36	Holly Beckman	12	0.25	0.08	1.00	25%	0.00					3rd	Alice Felton	0.3
37	Hope Hoffman	9	0.22	0	1.11	20%	0.00					Save Percentage
38	Jenna Thurlkill	11	0.18	0	0.55	33%	0.00					1st	Charlie Zetterberg	###
39	Lauren Martinsen	14	1.57	0.5	3.93	40%	0.00					2nd	Brooke Risser	86%
40	Lyla Dupont	10	0.20	0.2	1.80	11%	0.00					3rd	Emery Schmitz	81%
41	Nia Reilly	14	1.57	0.29	4.29	37%	0.14	78%				Games Played
42	Zuzu Gilman	12	0.25	0.17	0.42	60%	0.00					1st	Emery Schmitz	16
43	TEAM AVERAGE	10.47	0.54	0.14	1.61	26%	0.10	84%				2nd	Dempsey Meyers	14
44												3rd	Lauren Martinsen	14
Main

Cell Formulas
Range	Formula
L2:N4	L2	=SUM(Plains:E.O.S.!W2)
B3:J19	B3	=SUM(Plains:E.O.S.!B3,Plains:E.O.S.!M3,Plains:E.O.S.!B24,Plains:E.O.S.!M24)
B20:J20	B20	=SUM(B3:B19)
M8:N10	M8	=INDEX(SORT(CHOOSE({1,2},A3:A19,B3:B19*2+C3:C19),2,-1),SEQUENCE(3),{1,2})
M12:N14	M12	=INDEX(SORT(A3:B19,2,-1),SEQUENCE(3),{1,2})
M16:N18	M16	=INDEX(SORT(A3:C19,3,-1),SEQUENCE(3),{1,3})
M20:N22	M20	=INDEX(SORT(A3:H19,8,-1),SEQUENCE(3),{1,8})
D26:D42	D26	=C3/B26
E26:E42	E26	=D3/B26
F35:F42,F26:F33	F26	=B3/D3
H26,H41,H35,H33,H29:H30	H26	=H3/(G3+H3)
M26:N28	M26	=INDEX(SORT($A$26:$H$42,6,-1),SEQUENCE(3),{1,6})
C26:C27,C35:C42,C31:C33,C29	C26	=B3/B26
M30:N32	M30	=INDEX(SORT($A$26:$H$42,3,-1),SEQUENCE(3),{1,3})
G26:G42	G26	=G3/B26
M34:N36	M34	=INDEX(SORT($A$26:$H$42,4,-1),SEQUENCE(3),{1,4})
M38:N40	M38	=INDEX(SORT($A$26:$H$42,8,-1),SEQUENCE(3),{1,8})
M42:N44	M42	=INDEX(SORT(A26:B42,2,-1),SEQUENCE(3),{1,2})
B43:H43	B43	=AVERAGE(B26:B42)
Dynamic array formulas.

 

[KRice]

Just pull that column a little wider to accommodate the number (100 % needs more room).

 

[ExcelNoob2022]

Thank you KRICE! Got it working now, you rock!

 

[KRice]

I'm happy to help.