Adding row to table

[Luke777]

Hi,

I have a table to which I wish to add data. Previously, I've been simply copying an entire row to the next blank row (from one sheet of input data to an archive), but I've recently began to poke around with the power of using tables. With that said, I'm struggling to adjust to the new method of working a little. My source data is added to the archive when the macro is ran (QAT button) and by checking Column C. I was using the logic "for each range in C:C if range "Complete" entirerow.copy" and then pasting it to the archive sheet.

The below code is as far as I've got attempting to convert that logic, but obviously it doesn't work.

Sub MoveCompletedTasks2()



Dim sTasks As Worksheet

Dim cTasks As Worksheet

Dim archTable As ListObject



Dim newRow As ListRow



Set sTasks = ThisWorkbook.Sheets("Test")

Set Archive = ThisWorkbook.Sheets("Archive")

Set archTable = Archive.ListObjects("Archive")



Set newRow = archTable.ListRows.Add()



For Each cell In sTasks.Range("C:C")

If cell.Value = "Complete" Then newRow = cell.EntireRow.Value

Next cell



End Sub

Thanks for any help

 

[Alex Blakenburg]

Here is a starting point. This will only work if both tables have the same number of columns and that they are in the same order.
It also assumes that that in Test Row 1 is the headings and the data starts in Row 2

Sub MoveCompletedTasks2()

Dim sTasks As Worksheet
Dim wsTasks As Worksheet
Dim wsArchive As Worksheet
Dim tblArchive As ListObject
Dim newRow As ListRow

Set wsTasks = ThisWorkbook.Sheets("Test")
Set wsArchive = ThisWorkbook.Sheets("Archive")
Set tblArchive = wsArchive.ListObjects("Archive")


For Each rCell In wsTasks.Range("C2:C" & wsTasks.Cells(Rows.Count, "C").End(xlUp).Row)
    If rCell.Value = "Complete" Then
        Set newRow = tblArchive.ListRows.Add()
        newRow.Range.Value = Intersect(rCell.EntireRow, rCell.CurrentRegion).Value
    End If

Next rCell

End Sub