Adding More Conditions to an Existing Formula

[meppwc]

I have a formula that currently works correctly that is located in cell L2:
=IFERROR(VLOOKUP(B2,'Site Assignments'!$A$1:$D$131,4,FALSE),"ASK JON FOR INFO")

Now I want to add logic that says if cells F2 and I2 are blank, then leave L2 blank
I think what I need to add to the formula above is the following logic:
IF(AND(ISBLANK(F2), ISBLANK (I2),"",

So I came up with this formula:
=IF(AND(ISBLANK(F2), ISBLANK (I2),""),IFERROR(VLOOKUP(B2,'Site Assignments'!$A$1:$D$131,4,FALSE),"ASK JON FOR INFO"))

But that formula is returning #NAME ?
I suspect that by adding ISBLANK that might be triggering the error, but I am not sure
What am I doing incorrectly?

 

[steve the fish]

You misplaced your brackets:

=IF(AND(ISBLANK(F2),ISBLANK(I2)),"",IFERROR(VLOOKUP(B2,'Site Assignments'!$A$1:$D$131,4,FALSE),"ASK JON FOR INFO"))

 

[meppwc]

That is not triggering an error........which is good news............but it is still not giving the result that I am looking for............which is a blank cell...............I am not sure if this matters or not, but cells F2 and I2 do have formulas in them

 

[Joe4]

I am not sure if this matters or not, but cells F2 and I2 do have formulas in them

What EXACTLY are those formulas?
Can you post an example of each?

 

[meppwc]

F2 contains
=IFERROR(LOOKUP(9.99999999999999E+307,SEARCH(A2,$C$2:$C$600),$C$2:$C$600),"")
I2 contains
=IFERROR(LOOKUP(9.99999999999999E+307,SEARCH(A2,$D$2:$D$600),$C$2:$C$600),"")

 

[Joe4]

Try this instead:

[COLOR=#333333]=IF(AND(F2="",I2=""),"",IFERROR(VLOOKUP(B2,'Site Assignments'!$A$1:$D$131,4,FALSE),"ASK JON FOR INFO"))[/COLOR]

 

[meppwc]

That did it !!!!!..........thanks so much for all the help !!!!

 

[Joe4]

You are welcome. Glad we were able to help.

Yes, Excel doesn't consider the empty string ("") to be the same as a blank.