Add data validation list to cell in column A if data in column B

[breynolds0431]

Hi. I have a sheet titled "Combined" with data beginning in column B. I've been trying to come up with a macro that would add a validation list to cell A2 and then copy it down only to those rows that have data in column B. I can't get it to copy down, unfortunately. Below is the little code that I have working. Any thoughts?

 Sheets("Combined").Activate
 Range("A2").Select
 
  With Selection.Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
        xlBetween, Formula1:="=Acronyms"
        .IgnoreBlank = True
        .InCellDropdown = True
        .InputTitle = ""
        .ErrorTitle = ""
        .InputMessage = ""
        .ErrorMessage = ""
        .ShowInput = True
        .ShowError = True
    End With

Range("A2").Copy

 

[Fluff]

How about

Sub breynolds()
   With Sheets("Combined")
      With .Range("A2:A" & .Range("B" & Rows.Count).End(xlUp).Row).Validation
         .Delete
         .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
            xlBetween, Formula1:="=Acronyms"
         .IgnoreBlank = True
         .InCellDropdown = True
         .InputTitle = ""
         .ErrorTitle = ""
         .InputMessage = ""
         .ErrorMessage = ""
         .ShowInput = True
         .ShowError = True
      End With
   End With
End Sub

 

[breynolds0431]

Like a charm. Thank you so much!!

 

[Fluff]

You're welcome & thanks for the feedback