Add code at cursor position

[footoo]

The following procedure adds code to the active module at line 3.
How to add code to the active module at the cursor position?

Sub AddCode()

Dim wb As Workbook: Set wb = ActiveWorkbook
Dim xPro As VBIDE.VBProject
Dim xCom As VBIDE.VBComponent
Dim xMod As VBIDE.CodeModule

Set xPro = wb.VBProject
Set xCom = xPro.VBComponents(Application.VBE.ActiveCodePane.CodeModule.Name)
Set xMod = xCom.CodeModule

xMod.InsertLines 3, "Dim rng as range" & vbCrLf & _
    "Set rng = Range([A2], Cells(Rows.Count,""A"").end(3))" & vbCrLf

End Sub

 

[James006]

Hi,
In order to code your code ... Chip PEARSON has written the Bible of VBE:

Programming In The VBA Editor

www.cpearson.com

 

[footoo]

Hi,
In order to code your code ... Chip PEARSON has written the Bible of VBE:

Programming In The VBA Editor

www.cpearson.com

Thanks but already looked there and can't find what I want.

 

[James006]

A shortcut is probably to combine Delete and Add ... rather than Insert ...

 

[footoo]

A shortcut is probably to combine Delete and Add ... rather than Insert ...

Sorry. I don't understand your reply.

 

[James006]

Sorry for not being clear ...

Since you are Adding Code and just insert an instruction does not appear feasible ...

The Module which you want to modify ... can be Deleted ...and Re-Created including the initial modification you had planned to insert ...

Hope this clarifies

 

[footoo]

Thanks but that would be more complicated than what I am doing at present :
I have a userform with a listbox.
When an item on the listbox is selected, the code attached to that item is copied to the clipboard.
Then it is manually pasted to the macro.
It would nice to have the paste automated, but that involves pasting at the cursor position.

I want to do the same as an add-in available at Automacro - Download
I don’t want to use that add-in since it’s quite expensive.

 

[James006]

To get around your difficulty, couldn't you have your AddCode include a Select Case mirroring precisely the specific items in your List Box ...

 

[footoo]

But how do I programmatically paste to the cursor position in a macro?

 

[footoo]

I worked it out :

Sub AddCode()

Dim wb As Workbook: Set wb = ActiveWorkbook
Dim xPro As VBIDE.VBProject
Dim xCom As VBIDE.VBComponent
Dim xMod As VBIDE.CodeModule

Set xPro = wb.VBProject
Set xCom = xPro.VBComponents(Application.VBE.ActiveCodePane.CodeModule.Name)
Set xMod = xCom.CodeModule

Dim startline&, startcol&, endline&, endcol&
Application.VBE.ActiveCodePane.GetSelection startline, startcol, endline, endcol

xMod.InsertLines startline, "Dim rng as range" & vbCrLf & _
    "Set rng = Range([A2], Cells(Rows.Count,""A"").end(3))" & vbCrLf

End Sub