about getting info from two urls

[muhittinemmi]

Sub Dovizal()

      Dim qt As QueryTable, url As String, key As String, gid As String
 
      If ActiveSheet.QueryTables.Count > 0 Then ActiveSheet.QueryTables(1).Delete
      ActiveSheet.Cells.Clear
 
      url = "https://canlidoviz.com/doviz-kurlari/enpara"
 
        
      Set qt = ActiveSheet.QueryTables.Add(Connection:="URL;" & url, _
      Destination:=Range("a2"))
 
 
      With qt
          .WebSelectionType = xlAllTables
          .WebFormatting = xlWebFormattingNone
          .Refresh
           MsgBox "Veriler Güncellendi"
          
      End With
    
  End Sub

The data in the first url is saved from a2.

How can I add the 2nd url to be saved from a15 onwards

 

[Anthony47]

Try this version:

Sub Dovizal2()
    Dim qt As QueryTable, url As String, key As String, gid As String
    Dim Url2 As String, I As Long

    For I = ActiveSheet.QueryTables.Count To 1 Step -1
        ActiveSheet.QueryTables(I).Delete
    Next I
    Columns("A:Z").ClearContents
 
    url = "https://canlidoviz.com/doviz-kurlari/enpara"
    Set qt = ActiveSheet.QueryTables.Add(Connection:="URL;" & url, _
    Destination:=Range("a2"))
   
   
    With qt
        .WebSelectionType = xlAllTables
        .WebFormatting = xlWebFormattingNone
        .BackgroundQuery = False
        .Refresh
    End With
'
'second query:
    Url2 = "https://canlidoviz.com/doviz-kurlari/enpara"
    Set qt = ActiveSheet.QueryTables.Add(Connection:="URL;" & Url2, _
    Destination:=Range("A2").Offset(1 + Range(Range("A2").QueryTable.Name).Rows.Count))
    With qt
        .WebSelectionType = xlAllTables
        .WebFormatting = xlWebFormattingNone
        .BackgroundQuery = False
        .Refresh
    End With
   
    MsgBox "Veriler Güncellendii"
   
  End Sub

You will note that the macro doesn't set the "destination" of the second query "from a15 onwards", because the first query extracts (in my testing) up to line 23, and Excel doesn't accept that the second query overlaps with the first one; so the "destination" for the second query is set after the end of the first one

Try...

 

[muhittinemmi]

Thanks it works fine, problem solved

 

[Anthony47]

Thank you for the feedback