3 Digit Serie or Sequence

[audax48]

PLEASE I need help with a serie.
I have 3 columns A,B and C populated with numbers I want to Count how many times the numbers of the first Row (2, 1, and 5) any of them, are in Consecutive Rows

2 1 5
6 3 2
5 5 8
8 9 1
2 5 9
3 3 1
3 5 7
6 4 1
3 2 4
4 0 8
7 0 0
8 7 2
9 1 0
6 6 6
8 5 8
9 2 6
7 7 9
1 8 4
3 9 4
7 7 1
1 0 3
as Example the numbers 2, 1 and 5 the count will be 8
counting 2 2nd Row, 5 3rd Row,1 4th Row, 2 or 5 (count as 1) 5th Row, 1 6th Row, 5 7th Row, 1 8th Row and 2 9th Row (2,5,2,2 or 5,1,5,1,2), after that do the same following Row (6 3 2) in this case the count for that number is 0.

 

[bebo021999]

Is it are you looking for?

Book4
	A	B	C	D	E
1	2	1	5		8
2	6	3	2		0
3	5	5	8		2
4	8	9	1		2
5	2	5	9		0
6	3	3	1		3
7	3	5	7		0
8	6	4	1		2
9	3	2	4		1
10	4	0	8		3
11	7	0	0		2
12	8	7	2		0
13	9	1	0		0
14	6	6	6		0
15	8	5	8		0
16	9	2	6		1
17	7	7	9		0
18	1	8	4		3
19	3	9	4		0
20	7	7	1		1
21	1	0	3
Sheet2

Cell Formulas
Range	Formula
E1:E20	E1	=IFERROR(MATCH(0,MMULT(ISNUMBER(SEARCH("|"&A1:C1&"|","|"&A2:$A$21&"|"&B2:$B$21&"|"&C2:$C$21&"|"))+0,{1;1;1}),0)-1,COUNT(A2:$A$21))

 

[audax48]

THIS IS UNBELIEVE, What Formula is this, solve my problem Thank you VERY MUCH for taking your time for helping me.....Now let see if still you can help me with another question,,
Is there other solution if I want to choose all 1000 thousand combinations 000 - 999 instead of pick Row by row? SORRY for this new question but will solve 100% my problem if you find the formula, really you are the best THANK YOU

 

[Fluff]

What version of Excel are you using?

I suggest that you update your Account details (or click your user name at the top right of the forum) so helpers always know what Excel version(s) & platform(s) you are using as the best solution often varies by version. (Don’t forget to scroll down & ‘Save’)

 

[KRice]

Here is a slightly shorter version using a similar approach, but forming the "found below" array differently:

Book1
	A	B	C	D	E	F
1	2	1	5		8	8
2	6	3	2		0	0
3	5	5	8		2	2
4	8	9	1		2	2
5	2	5	9		0	0
6	3	3	1		3	3
7	3	5	7		0	0
8	6	4	1		2	2
9	3	2	4		1	1
10	4	0	8		3	3
11	7	0	0		2	2
12	8	7	2		0	0
13	9	1	0		0	0
14	6	6	6		0	0
15	8	5	8		0	0
16	9	2	6		1	1
17	7	7	9		0	0
18	1	8	4		3	3
19	3	9	4		0	0
20	7	7	1		1	1
21	1	0	3
Sheet1

Cell Formulas
Range	Formula
E1:E20	E1	=IFERROR(MATCH(0,MMULT(ISNUMBER(SEARCH("|"&A1:C1&"|","|"&A2:$A$21&"|"&B2:$B$21&"|"&C2:$C$21&"|"))+0,{1;1;1}),0)-1,COUNT(A2:$A$21))
F1:F20	F1	=IFERROR(MATCH(0,MMULT((A2:C$21=A1)+(A2:C$21=B1)+(A2:C$21=C1),{1;1;1}),0)-1,COUNT(A2:A$21))

I'm not clear on what you mean by...

I want to choose all 1000 thousand combinations 000 - 999 instead of pick Row by row

 

[audax48]

THANK A LOT YOU ARE AMAZING SOLVED MY PROBLEM