# Codigo VBA para Reconocer un Area Marcada



## actjfc (Aug 15, 2008)

Amigos,

¿Cómo se indica o reconoce en un codigo BVA cualquier área sombreada que uno ha seleccionado previamente? Una vez que yo haya sombreado el área voy a copiarla, moverla, etc., o simplemente hacer funcionar el resto del macro, pero aplicado a esa área especificamente, que puede cambiar, por eso se requiere que sea solo el area que el usuario haya decidido marcar.

Puede alguien decirme cómo hacer esto.

Gracias,


----------



## Greg Truby (Aug 15, 2008)

No sé si le estoy entendiendo bien.  Pero creo que lo que usted quiere es usar el objeto _selection_ y/o una variable tipo rango.

```
Sub EjemploSeleccion()
    Dim rngSeleccion As Excel.Range
    
    '// si no es un rango seleccionado (puede ser
    '// es una forma o control) entonces salimos
    If TypeName(Selection) <> "Range" Then Exit Sub
    
    Set rngSeleccion = Selection
    
    With rngSeleccion
        .Interior.Color = vbBlue
        With .Font
            .Color = vbYellow
            .Bold = True
        End With
    End With
    
End Sub
```


----------



## actjfc (Aug 15, 2008)

Muchas gracias, su ejemplo me sirvió de mucho. Realmente lo que yo necesitaba era la instrucción "Dim rngSeleccion As Excel.Range" de alli en adelante pude hacer lo que se requeria:

Sub HCopy()
    Dim rngSeleccion As Excel.Range
    Selection.Copy
    Workbooks.Add
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteValues
    Selection.PasteSpecial Paste:=xlPasteFormats
End Sub

Ahora tengo un pequeño problema, la selección puede contener una o muchas columnas, pero cada columna dentro de la selección puede tener un ancho diferente, y variable dependiendo del rango seleccionado. Entonces depues de realizar la copia, en la hoja nueva aparecen ####### en algunas celdas que contienen números muy grandes. 

¿Cómo puedo modificar el código para que, sin importar el número de columnas en la selección o su ancho variable, la copia del rango siempre se vea correctamente? Esto resultaria en una solución elegante a mi problema original.

Muchas gracias.


----------



## Greg Truby (Aug 15, 2008)

Favor leer los comentarios ubicados dentro de cada bloque de código.
	
	
	
	
	
	



```
Sub HCopy()
 
    '// usted no usó este variable.  En su macro está sobrando
    Dim rngSeleccion As Excel.Range
 
    '// ¿y qué pasa si el usuario ha seleccionado una forma o gráfico?
    Selection.Copy
 
    Workbooks.Add
    '// es un hábito débil suponer cual objeto está seleccionado
    '// mejor estar seguro.  En este caso no estamo seguro a cual
    '// cuaderno ni a cual hoja pertenece el rango.
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteValues
    Selection.PasteSpecial Paste:=xlPasteFormats
End Sub
 
 
Sub HCopy2()
 
    Dim rngSeleccion As Excel.Range, _
        wbkNuevo As Excel.Workbook
 
    '// si no es un rango seleccionado (puede ser
    '// es una forma o control) entonces salimos
    If TypeName(Selection) <> "Range" Then Exit Sub
 
    Set rngSeleccion = Selection
 
    '// ahora estamos seguro que podemos agarrar
    '// el cuaderno deseado por medio de wbkNuevo
    Set wbkNuevo = Workbooks.Add
 
    '// sabemos cual rango estamos copiando
    '// note que el cuaderno de fuente no es el
    '// cuaderno activo.
    rngSeleccion.Copy
 
    '// ahora estamos seguros con cual hoja trabajamos.
    With wbkNuevo.Sheets(1).Range("A1")
        .PasteSpecial Paste:=xlPasteValues
        .PasteSpecial Paste:=xlPasteFormats
        .PasteSpecial Paste:=xlPasteColumnWidths
    End With
 
End Sub
```


----------



## actjfc (Aug 15, 2008)

Gracias, funciona perfecto y es una solución elegante. Ahora me doy cuenta que tengo unos formatos condicionales que se dañan cuando hago la copia.

Para finalizar, ¿Como modifico la hoja destino, para que borre todos los formatos condicionales de una sola vez? (delete ALL conditional formats within wbkNuevo.Sheets(1) all at once!)

Gracias otra vez,


----------



## Greg Truby (Aug 15, 2008)

Prenda la grabadora de macros (macro recorder) y házlo a mano. Después trate de incorporar las líneas apropiadas al código que ya le di. 

(No es que no le puedo decir, sino haciéndolo usted mismo, usted aprenda mucho más. Pregúntele a _cgcamal_, soy profesor duro en ese aspecto. :wink


----------



## actjfc (Aug 15, 2008)

Gracias, ensayo y error es la mejor forma de aprender (Trial and error)

Me ayudó mucho, muchas gracias.


----------



## actjfc (Aug 15, 2008)

Agregué al final, 

Cells.Select
Selection.FormatConditions.Delete

Y funciona bien.

Gracias.


----------



## Greg Truby (Aug 15, 2008)

actjfc said:


> ...
> 
> 
> 
> ...


¿Funciona? Sí. ¿Decir que funciona *bien*? Otra cosa. Generalmente _selection.method_ es vudú débil. Vudú fuerte es especificar el objeto. En el caso suyo, una aplicación mejor hubiera sido

```
With wbkNuevo.Sheets(1)
        With .Range("A1")
            .PasteSpecial Paste:=xlPasteValues
            .PasteSpecial Paste:=xlPasteFormats
            .PasteSpecial Paste:=xlPasteColumnWidths
        End With
        .Cells.FormatConditions.Delete
    End With
```
o tal vez

```
With wbkNuevo.Sheets(1)
        With .Range("A1")
            .PasteSpecial Paste:=xlPasteValues
            .PasteSpecial Paste:=xlPasteFormats
            .PasteSpecial Paste:=xlPasteColumnWidths
        End With
        .UsedRange.FormatConditions.Delete
    End With
```


----------



## actjfc (Aug 15, 2008)

Gracias otra vez. Es un código muy elegante.


----------

