6 day work week with workday function?????

Could you explain a bit about the problem you're trying to solve? Perhaps the WORKDAY function isn't appropriate here.

I have a schedule of activities that have durations set to each and it is currently on a 5 day a week calendar but I would the option to see the effect if it was on a 6 day a week calendar.

This would take a pretty extensive formula. In order for someone to go down that road, it would be helpful to know:
1) What six days? (ie no Sunday)
2) Are you using the holidays argument?

yeah, no sunday's and have the holidays set in

The following formula from Harlan Grove (Microsoft Excel MVP) mimics Excel’s Networkdays function:

=SUMPRODUCT(--(COUNTIF(Holidays,ROW(INDIRECT(A2&":"&B2)))=0),--(WEEKDAY(ROW(INDIRECT(A2&":"&B2)),3)<6))

Where:
A2: 1 November 03 (start date)
B2: 31 March 04 (end date)

“Holidays” is a named range that covers holidays for the year.

The above formula returns an identical result to:

=NETWORKDAYS(A2,B2,Holidays) but includes Saturdays and excludes Sundays.

Look at the last part of Mr. Grove’s formula:

WEEKDAY(……),3)<6))

From Excel’s Help file:

WEEKDAY(serial_number,return_type)

When the return type is 3 (as per Mr. Grove’s formula), the Weekday functions returns 0 (Monday) through 6 (Sunday). So, to include Saturday and exclude Sunday (days 5 and 6), the formula has “<6”.

To include Saturdays and Sundays, change the formula to:

WEEKDAY(……),3)<7))

Works for me on limited test data.

HTH

Mike

As an alternative to Ekim's (and indirectly, Harlan Grove's) formulation, perhaps the following:

The formula in C2 is:

=NETWORKDAYS(A2,B2,Holidays)+INT(B2/7)-INT(A2/7)+INT(WEEKDAY(A2)/7)

while the formula in D2 is as posted in the reply immediately above.

I offer this alternative, since recently some experts on this board seem to be cautioning against the overuse of array formulations, and because I have long championed this alternative formulation. In short, the simplest, non-array oriented formula for counting the number of a particular weekday between any 2 dates (inclusive) is:

=INT((End-Wkday)/7)-INT((Start-Wkday)/7)+INT(WEEKDAY(Start-Wkday)/7)

where Start is the starting date of interest, End is the ending date, and Wkday = 1,2,3,4,5,6, or 7, for Sunday through Saturday, respectively. Note that Wkday can be omitted for Saturday, so that the formula simplifies to:

=INT(Stop/7)-INT(Start/7)+INT(WEEKDAY(Start)/7)

when you want to count the number of Saturdays between any 2 dates. Note that either formula is considerably faster than alternative expressions that return the same answer, such as:

=SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(Start&":"&End)))=Wkday))

when dealing with large numbers of calculations. See also:

http://www.mrexcel.com/board2/viewtopic.php?t=61643
http://www.mrexcel.com/board2/viewtopic.php?t=63010
http://www.mrexcel.com/board2/viewtopic.php?t=67153

--Tom McClain