color palette

lpvdsteen · Nov 8, 2003

Hi
Is there a way to, from VBA, have the colorpalette pop up and allow the user to select a color which VBA can the assign to a designated cel, listbox or whatever. With this palette in the system, it seems so pointless to redisign it on a userform.
Luke

Ivan F Moala · Nov 8, 2003

Yes it is...here is One way..amend as required or post back
for Help.

Note it is NOT the Excel Dialog

<pre>Option Explicit
'// Ivan F Moala
'// http://www.XcelFiles.com

Private Type CHOOSECOLOUR
lStructSize As Long
hwndOwner As Long
hInstance As Long
rgbResult As Long
lpCustColors As String
flags As Long
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type

Declare Function ChooseColorA _
Lib "Comdlg32" ( _
lpChooseColor As CHOOSECOLOUR) _
As Long

Declare Function FindWindowA _
Lib "User32" ( _
ByVal lpClassName As Any, _
ByVal lpWindowName As String) _
As Long

Function SelectColour(Code_RGB) As Boolean
Dim CColor As CHOOSECOLOUR
Dim CustColors As String * 16

With CColor
.lStructSize = 36
.hwndOwner = FindWindowA(0&, Application.Caption)
.lpCustColors = CustColors
.flags = 2
End With

If ChooseColorA(CColor) = 0 Then Exit Function
Code_RGB = CColor.rgbResult
SelectColour = True

End Function

Sub Tester()
Dim Code_RGB As Long

If Not SelectColour(Code_RGB) Then Exit Sub

MsgBox "The RGB code you chose:=" & Code_RGB & vbCr & _
"Red:=" & RGBRed(Code_RGB) & vbCr & _
"Green:=" & RGBGreen(Code_RGB) & vbCr & _
"Blue:=" & RGBBlue(Code_RGB)

'// Activecell colour
ActiveCell.Interior.Color = Code_RGB

'// OR Selection
'Selection.Interior.Color = Code_RGB

End Sub

Public Function RGBRed(RGBCol As Long) As Integer
'// Return the Red component from an RGB Coloor
RGBRed = RGBCol And &HFF
End Function

Public Function RGBGreen(RGBCol As Long) As Integer
'// Return the Green component from an RGB Colour
RGBGreen = ((RGBCol And &H100FF00) / &H100)
End Function

Public Function RGBBlue(RGBCol As Long) As Integer
'// Return the Blue component from an RGB Colour
RGBBlue = (RGBCol And &HFF0000) / &H10000
End Function
</pre>

lpvdsteen · Nov 11, 2003

Haven'tbeen on the net lately, so a bit late in my reaction. (work.work.work)

This works great, however

I was looking for the excel-systems palette. The problem with the windows palette is that is is too advanced for excel (excel can only work with a limited amount of colours and so when you select a particular colour it may turn out completely different.) Can i adress this excel-palette in the same way and how, I presume (hope) it is just another library?

Luke

Iridium · Nov 12, 2003

See also

http://j-walk.com/ss/excel/tips/tip49.htm

HTH

Ivan F Moala · Nov 12, 2003

Iridium said:
See also

http://j-walk.com/ss/excel/tips/tip49.htm

HTH

Ah, yes...a good choice!!

lpvdsteen · Nov 12, 2003

Ok, that does the trick. Tought me a deal again as well, fun. I was hesitant to use a form to reinvent the wheel, but the amount of data used it minimal, and the function extreem. Thanks

Luke

babs · Dec 16, 2003

How about this one ?

Application.Dialogs.Item(xlDialogPatterns).Show

magotha · Jan 22, 2013

color palette

color palette

lpvdsteen

Board Regular

Ivan F Moala

MrExcel MVP

lpvdsteen

Board Regular

Iridium

Well-known Member

Ivan F Moala

MrExcel MVP

lpvdsteen

Board Regular

babs

Board Regular

magotha

New Member

Similar threads

Forum statistics

Share this page

color palette

Board Regular

MrExcel MVP

Board Regular

Well-known Member

MrExcel MVP

Board Regular

Board Regular

New Member

Similar threads

Forum statistics

Share this page

We've detected that you are using an adblocker.

Which adblocker are you using?

Disable AdBlock

Disable AdBlock Plus

Disable uBlock Origin

Disable uBlock