Macro to delete rows containing certain values

Sub Filter_Copy_Delete()
    Dim lRowSource As Long, lRowTarget As Long, lCol As Long
    Dim rngToCopy As Range
    Application.ScreenUpdating = False
    On Error Resume Next
 
    With Sheets("Source Data")
        .AutoFilterMode = False
        lRowSource = .Cells.Find(What:="*", After:=.Range("A1"), _
            SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        lCol = .Cells.Find(What:="*", After:=.Range("A1"), _
            SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
 
        With .Range("A1", .Cells(lRowSource, lCol))
           .AutoFilter Field:=16, Criteria1:=">=8/1/2016", _
                Operator:=xlOr, Criteria2:="#VALUE!"
            .AutoFilter Field:=14, Criteria1:="<2", _
                Operator:=xlAnd, Criteria2:=">=-.2"
            Set rngToCopy = .Offset(2).Resize(.Rows.Count - 2) _
                .SpecialCells(xlCellTypeVisible)
        End With
    End With
    If Not rngToCopy Is Nothing Then
        rngToCopy.Copy
        With Sheets("Data History")
            lRowTarget = .Cells.Find(What:="*", After:=.Range("A1"), _
                SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
            .Cells(lRowTarget + 1, 1).PasteSpecial (xlPasteValues)
        End With
    End If
    With Sheets("Source Data")
         .AutoFilterMode = False
        '---Remove the ' to delete all but top 2 rows of Source Data sheet
      '    .Rows("3:" & lRowSource).EntireRow.Delete
  End With
    Set rngToCopy = Nothing
End Sub