Image viewer in excel

'=============================================================
'- GET A PICTURE FROM A FOLDER INTO A WORKSHEET
'- DOUBLE CLICK CELL CONTAINING PICTURE FILE NAME TO OPEN IT
'- Code goes into Worksheet module. Right click tab. View Code
'- Brian Baulsom 2008
'==============================================================
'================================================================================
'- DOUBLE CLICK CODE
'================================================================================
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim MyFolder As String
    Dim MyFile As String
    Dim ws As Worksheet
    Dim MyCell As Range         ' cell for picture
    Dim MyGallery As ShapeRange ' ALL PICTURES IN THE SHEET
    '----------------------------------------------------------------------------
    '- Folder & File name
    MyFolder = "F:\My Pictures\"
    MyFile = MyFolder & Target.Value    ' CELL VALUE
    '------------------------------------------------------
    Application.ScreenUpdating = False
    Set ws = ActiveSheet
    '------------------------------------------------------
    '- clear all existing pictures
    On Error Resume Next        ' might be no pictures yet
    Set MyGallery = ws.Pictures.ShapeRange
    MyGallery.Delete
    On Error GoTo 0             ' reset error trap to normal
    '------------------------------------------------------
    '- CELL SIZE
    Set MyCell = ws.Range("D1")
    MyCell.ColumnWidth = 21
    MyCell.RowHeight = 102
    '------------------------------------------------------
    '- INSERT PICTURE & RESIZE TO SAME AS CELL
    ws.Pictures.Insert(MyFile).Select
    With Selection
        .Top = MyCell.Top
        .Left = MyCell.Left
        .Width = MyCell.Width
        .Height = MyCell.Height
        .Placement = xlMoveAndSize
        .PrintObject = True
    End With
    '------------------------------------------------------
    '- remove focus from picture
    MyCell.Select
    Application.ScreenUpdating = True
End Sub
'============================================================================

'=========================================================
'- GET PICTURE FILE NAMES FROM A FOLDER INTO A WORKSHEET
'=========================================================
Private Sub GetPictures()
    Dim MyFolder As String
    Dim MyFile As String
    Dim rw As Long
    '-----------------------------------------------------
    MyFolder = "F:\My Pictures\"
    MyFile = Dir(MyFolder & "*.jpg")
    rw = 1      ' row number
    '-----------------------------------------------------
    Do While MyFile <> ""
        ActiveSheet.Cells(rw, "A").Value = MyFile
        rw = rw + 1
        MyFile = Dir
    Loop
    '-----------------------------------------------------
End Sub
'===========================================================