The weirdest thing seems to be happening in my worksheet I have a field that is the last of my header row and it is unpopulated most of the time with the exception of my header. I am attempting to save this worksheet as tab delimited text to import the data in an application that was written. However when I save as txt the tab for the last field disappears after 16 records everytime?? I need to have all thirteen fields recognized for my import process to work and sometimes the 13th maybe populated?? anyone have any ideas as to why excel would choose not to recognize this blank column after 16 records everytime and what I could do to fix this?
-
If you would like to post, please check out the MrExcel Message Board FAQ and register here. If you forgot your password, you can reset your password.
Saving as Tab delimited... missing fields??
- Thread starter kidcrust
- Start date
Not weird at all "It Is A Feature Not A Bug" (at least that'ts what we expect Microsoft to tell us) 
It's all about Excel trying to do our thinking for us. So we have to get down to "grass roots basics" and go from there. Here is something I prepared earlier.
It's all about Excel trying to do our thinking for us. So we have to get down to "grass roots basics" and go from there. Here is something I prepared earlier.
Code:
'===========================================================================
'- MACRO TO CONVERT WORKSHEET TO PIPE OR TAB (or other) DELIMITED TEXT FILE
'- WS HAS TO BE SET UP AS A SIMPLE TABLE. RUN MACRO FROM THE SHEET
'- Brian Baulsom April 2002
'===========================================================================
'-
Sub EXPORT_SHEET_TO_TEXT()
Dim FileName As String ' .txt FILENAME AS WORKSHEET
Dim MyRow As Long
Dim MyCol As Integer
Dim MyReturn As String
Dim ws As Worksheet
Dim LastRow As Long
Dim ColumnCount As Integer
Dim MyDelimiter As String
'---------------------------------------------------------------------
Application.Calculation = xlCalculationManual
'- set the delimiter required
'MyDelimiter = "|" ' pipe
MyDelimiter = Chr(9) ' tab
'---------------------------------------------------------------------
Set ws = ActiveSheet
MyReturn = Chr(13)
FileName = ws.Name & ".txt"
'----------------------------------------------------------------------
'- get number of rows (to allow for blank cells)
LastRow = ws.Cells.Find(What:="*", SearchDirection:=xlPrevious, _
SearchOrder:=xlByRows).Row
'----------------------------------------------------------------------
'- get number of columns
ColumnCount = ws.Cells.Find(What:="*", SearchDirection:=xlPrevious, _
SearchOrder:=xlByColumns).Column
'----------------------------------------------------------------------
'- EXPORT TO FILE
Open FileName For Append As #1
'- loop through rows & columns
For MyRow = 1 To LastRow
For MyCol = 1 To ColumnCount
Print #1, ws.Cells(MyRow, MyCol).Value;
If MyCol < ColumnCount Then Print #1, MyDelimiter; ' Column
Next
Print #1, MyReturn; ' end of line Return
Next
'----------------------------------------------------------------------
Close #1
MsgBox ("Done")
Application.Calculation = xlCalculationAutomatic
End Sub
'=========== END OF PROCEDURE =============================================
Upvote
0
