Consolidate Numerous Files

FromFileName = "C" & ListSheet.Cells(FromRow, "A").Value

'=============================================================================
'- GET DATA FROM FILES LISTED IN A WORKSHEET (column A)
'- Data from Worksheet called "Load" range A1:G125 in each workbook
'- List contains path & file name
'- Brian Baulsom September 2008
'=============================================================================
Sub GET_DATA_FROM_FILE_LIST()
    Dim ListSheet As Worksheet  ' worksheet with list
    Dim FromRow As Long         ' Item row in list
    Dim LastRow As Long         ' last row of list
    Dim ToSheet As Worksheet    ' worksheet called "Consolidation"
    Dim ToRow As Long           ' target row in consolidation
    Dim FromFileName As String  ' source workbook name
    Dim FromBook As Workbook    ' source file
    Dim FromSheet As Worksheet  ' source worksheets all called "Load"
    '-------------------------------------------------------------------------
    '- initialise variables
    Set ListSheet = Worksheets("MyList")
    LastRow = ListSheet.Range("A65536").End(xlUp).Row
    Set ToSheet = Worksheets("Consolidation")
    '-------------------------------------------------------------------------
    '- LOOP THROUGH THE LIST & GET WORKBOOKS
    For FromRow = 1 To LastRow
        '- source file name
        FromFileName = ListSheet.Cells(FromRow, "A").Value
        '----------------------------------------------------------------------
        '- show progress in status bar
        Application.StatusBar = FromRow & "\" & LastRow & " -> " & FromFileName
        '----------------------------------------------------------------------
        '- open workbook
        Set FromBook = Workbooks.Open(FromFileName)
        Set FromSheet = FromBook.Worksheets("Load")
        '---------------------------------------------------------------------
        '- Get ToRow
        ToRow = ToSheet.Range("A65536").End(xlUp).Row + 1
        '---------------------------------------------------------------------
        '- copy/paste data
        FromSheet.Range("A1:G125").Copy Destination:=ToSheet.Cells(ToRow, "A")
        '---------------------------------------------------------------------
        '- close source workbook
        FromBook.Close
        '---------------------------------------------------------------------
    Next
    '-------------------------------------------------------------------------
    MsgBox ("Done")
    Application.StatusBar = False
End Sub
'=============================================================================